Wikidata api 如何根据维基百科页面 id 获取一些属性

Question

所以我有这个页面 ID 12517871：https ://fr.wikipedia.org/wiki ? curid = 12517871

我想从这里的底部获取标识符https://www.wikidata.org/wiki/Q64007200

使用 sparql，但我不知道该怎么做。

我知道我必须使用类似的东西

    SELECT ?sitelink ?itemLabel ?sitelinkLabel ?article ?cid WHERE {
  ?sitelink schema:isPartOf <https://fr.wikipedia.org/>.
}

但后来我不知道如何按页面 id 搜索以及如何获取标识符（imdb、allocine ..）

谢谢

编辑：我正在使用此查询https://w.wiki/GD5但它随机不返回任何内容。要测试这种随机性，请更改“限制”上的数字

SELECT ?propertyclaim ?value ?item WHERE {
  hint:Query hint:optimizer "None" .
  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:endpoint "fr.wikipedia.org" .
    bd:serviceParam wikibase:api "Generator" .
    bd:serviceParam mwapi:generator "revisions" .
    bd:serviceParam mwapi:pageids "12148688" .
    ?item_ wikibase:apiOutputItem mwapi:item .
    bd:serviceParam wikibase:limit 3
  }
  BIND (COALESCE(?item_, " ") AS ?item) 
  ?item ?propertyclaim ?value .  
  ?property wikibase:directClaim ?propertyclaim . 
  ?property wikibase:propertyType wikibase:ExternalId .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }} 

Answer 1

由于您有一个 pageid 而不是文章标题，这使得查询有点麻烦。

您需要使用Mediawiki API 服务从 SPARQL 调用 Mediawiki API 以获取维基百科页面 id 的 Wikidata 项目 id。

获得商品 ID 后，您可以查询该商品的所有外部标识符。总之，查询如下所示：

SELECT ?propertyLabel ?value WHERE {
  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:endpoint "fr.wikipedia.org" .
    bd:serviceParam wikibase:api "Generator" .
    bd:serviceParam mwapi:generator "revisions" .
    bd:serviceParam mwapi:pageids "12517871" .
    ?item wikibase:apiOutputItem mwapi:item .
  }
  ?property wikibase:propertyType wikibase:ExternalId .
  ?property wikibase:directClaim ?propertyclaim .
  ?item ?propertyclaim ?value   
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }        
}