Haskell：结合存在量词和全称量词意外失败

Question

我正在尝试使用 GHC 8.6.5 版在 Haskell 中对以下逻辑含义进行建模：

(∀ a. ¬ Φ(a)) → ¬ (∃ a: Φ(a))

我使用的定义如下：

{-# LANGUAGE RankNTypes, GADTs #-}

import Data.Void

-- Existential quantification via GADT
data Ex phi where
  Ex :: forall a phi. phi a -> Ex phi

-- Universal quantification, wrapped into a newtype
newtype All phi = All (forall a. phi a)

-- Negation, as a function to Void
type Not a = a -> Void

-- Negation of a predicate, wrapped into a newtype
newtype NotPred phi a = NP (phi a -> Void)

-- The following definition does not work:
theorem :: All (NotPred phi) -> Not (Ex phi)
theorem (All (NP f)) (Ex a) = f a

在这里，GHC 拒绝执行theorem并显示以下错误消息：

* Couldn't match type `a' with `a0'
  `a' is a rigid type variable bound by
    a pattern with constructor:
      Ex :: forall a (phi :: * -> *). phi a -> Ex phi,
    in an equation for `theorem'
    at question.hs:20:23-26
* In the first argument of `f', namely `a'
  In the expression: f a
  In an equation for `theorem': theorem (All (NP f)) (Ex a) = f a
* Relevant bindings include
    a :: phi a (bound at question.hs:20:26)
    f :: phi a0 -> Void (bound at question.hs:20:18)

我真的不明白为什么 GHC 不应该能够匹配这两种类型。以下解决方法编译：

theorem = flip theorem' where
    theorem' (Ex a) (All (NP f)) = f a

对我来说， 的两种实现theorem是等效的。为什么GHC只接受第二个？

Answer 1

当您将模式All prf与 type 的值进行匹配时All phi，prf将提取为 type 的多态实体forall a. phi a。在这种情况下，您将获得一个no :: forall a. NotPred phi a. 但是，您不能对这种类型的对象执行模式匹配。毕竟，它是一个从类型到值的函数。您需要将其应用于特定类型（称为_a），然后您将获得no @_a :: NotPred phi _a，现在可以匹配以提取f :: phi _a -> Void. 如果你扩展你的定义......

{-# LANGUAGE ScopedTypeVariables #-}
-- type signature with forall needed to bind the variable phi
theorem :: forall phi. All (NotPred phi) -> Not (Ex phi)
theorem prf wit = case prf of
    All no -> case no @_a of -- no :: forall a. NotPred phi a
        NP f -> case wit of -- f :: phi _a -> Void
            Ex (x :: phi b) -> f x -- matching against Ex extracts a type variable, call it b, and then x :: phi b

所以问题是，应该使用什么类型_a？好了，我们正在申请f :: phi _a -> Void以x :: b（其中b存储的类型变量wit），所以我们应该设置_a := b。但这是一个范围界定违规。b只能通过匹配来提取Ex，这发生在我们特化no和提取之后f，所以f的类型不能依赖于b。因此，在_a不让存在变量脱离其作用域的情况下，没有任何选择可以使这项工作正常进行。错误。

正如您所发现的，解决方案是Ex在将该类型应用于no.

theorem :: forall phi. All (NotPred phi) -> Not (Ex phi)
theorem prf wit = case wit of
    Ex (x :: phi b) -> case prf of
        All no -> case no @b of
            NP f -> f x
-- or
theorem :: forall phi. All (NotPred phi) -> Not (Ex phi)
theorem (All no) (Ex x) | NP f <- no = f x