Erlang 中二进制字符串的棘手模式匹配

Question

我正在使用 Erlang 在电子邮件服务器和 Spamassassin 之间发送消息。

我想要实现的是检索 SA 完成的测试以生成报告（我正在做某种邮件测试程序）

当 SpamAssassin 回答（通过原始 TCP）时，它会发送一个如下所示的二进制字符串：

<<"SPAMD/1.1 0 EX_OK\r\nContent-length: 728\r\nSpam: True ; 6.3 / 5.0\r\n\r\nReceived: from localhost by debpub1.cs2cloud.internal\r\n\twith SpamAssassin (version 3.4.2);\r\n\tSat, 04 Jan 2020 18:24:37 +0100\r\nFrom: bibi <bibi@XXXXX.local>\r\nTo: <aZphki8N05@XXXXXXXX>\r\nSubject: i\r\nDate: Sat, 4 Jan 2020 18:24:36 +0100\r\nMessage-Id: <3b68dede-f1c3-4f04-62dc-f0b2de6e980a@PPPPPP.local>\r\nX-Spam-Checker-Version: SpamAssassin 3.4.2 (2018-09-13) on\r\n\tdebpub1.cs2cloud.internal\r\nX-Spam-Flag: YES\r\nX-Spam-Level: ******\r\nX-Spam-Status: Yes, score=6.3 required=5.0 tests=BODY_SINGLE_WORD,\r\n\tDKIM_ADSP_NXDOMAIN,DOS_RCVD_IP_TWICE_C,HELO_MISC_IP,\r\n\tNO_FM_NAME_IP_HOSTN autolearn=no autolearn_force=no version=3.4.2\r\nMIME-Version: 1.0\r\nContent-Type: multipart/mixed; boundary=\"----------=_5E10CA56.0200B819\"\r\n\r\n">>

我把我想拿起的物品加粗：

• BODY_SINGLE_WORD
• DKIM_ADSP_NXDOMAIN
• DOS_RCVD_IP_TWICE_C
• HELO_MISC_IP
• NO_FM_NAME_IP_HOSTN

然后我想像这样序列化：[<<"DKIM_ADSP_NXDOMAIN">>,<<"DOS_RCVD_IP_TWICE_C">>,...]

但这并不容易，术语没有常规的“分隔符”，有 \r\n 或 \r\n\t

我以该表达式开头（在二进制字符串上拆分 ','），但结果不完整

split(BinaryString, ",", all),
case lists:member(<<"HELO_MISC_IP">>, Data3 ) of
            true -> ; %push the result in a database
            false -> ok
end;

我希望我可以重新开始，并通过递归使用循环（并且因为它是一种干净且不错的循环方式），但在我看来，这种情况毫无意义……

split(BinaryString, Idx, Acc) ->
case BinaryString of
    <<"tests=",_This:Idx/binary, Char, Tail/binary>> ->
                case lists:member(Char, BinaryString ) of
                    false ->
                        split(BinaryString, Idx+1, Acc);
                    true -> 
                           case Tail of
                                    <<Y/binary, _Tail/binary>> ->
                                    %doing something
                                    <<_Yop2/binary>> ->
                                    %doing somethin else
                           end
                 end;

问题是我不明白如何以可接受和干净的方式实现这一目标

如果有人能给我一只手，那将是非常非常可观的。

你的

Answer 1

一种解决方案是匹配您正在寻找的二进制文件的部分：

Data = <<"SPAMD/1.1 0 EX_OK\r\nContent-length: 728\r\nSpam: True ; 6.3 / 5.0\r\n\r\nReceived: from localhost by debpub1.cs2cloud.internal\r\n\twith SpamAssassin (version 3.4.2);\r\n\tSat, 04 Jan 2020 18:24:37 +0100\r\nFrom: bibi <bibi@XXXXX.local>\r\nTo: <aZphki8N05@XXXXXXXX>\r\nSubject: i\r\nDate: Sat, 4 Jan 2020 18:24:36 +0100\r\nMessage-Id: <3b68dede-f1c3-4f04-62dc-f0b2de6e980a@PPPPPP.local>\r\nX-Spam-Checker-Version: SpamAssassin 3.4.2 (2018-09-13) on\r\n\tdebpub1.cs2cloud.internal\r\nX-Spam-Flag: YES\r\nX-Spam-Level: ******\r\nX-Spam-Status: Yes, score=6.3 required=5.0 tests=BODY_SINGLE_WORD,\r\n\tDKIM_ADSP_NXDOMAIN,DOS_RCVD_IP_TWICE_C,HELO_MISC_IP,\r\n\tNO_FM_NAME_IP_HOSTN autolearn=no autolearn_force=no version=3.4.2\r\nMIME-Version: 1.0\r\nContent-Type: multipart/mixed; boundary=\"----------=_5E10CA56.0200B819\"\r\n\r\n">>,
Matches = binary:compile_pattern([<<"BODY_SINGLE_WORD">>,<<"DKIM_ADSP_NXDOMAIN">>,<<"DOS_RCVD_IP_TWICE_C">>,<<"HELO_MISC_IP">>,<<"NO_FM_NAME_IP_HOSTN">>]),
[binary:part(Data, PosLen) || PosLen <- binary:matches(Data, Matches)].

在 Erlang shell 中执行以上三行返回：

[<<"BODY_SINGLE_WORD">>,<<"DKIM_ADSP_NXDOMAIN">>, <<"DOS_RCVD_IP_TWICE_C">>,<<"HELO_MISC_IP">>, <<"NO_FM_NAME_IP_HOSTN">>]

这提供了所需的结果，但它可能不安全，因为它不会尝试验证输入是否有效或匹配是否发生在有效边界上。

一种可能更安全的方法依赖于这样一个事实，即输入二进制文件类似于 HTTP 结果，因此可以使用内置的 Erlang 解码器对其进行部分解析。以下parse/1,2函数用于erlang:decode_packet/3从输入中提取信息：

parse(Data) ->
    {ok, Line, Rest} = erlang:decode_packet(line, Data, []),
    parse(Line, Rest).
parse(<<"SPAMD/", _/binary>>, Data) ->
    parse(Data, []);
parse(<<>>, Hdrs) ->
    Result = [{Key,Value} || {http_header, _, Key, _, Value} <- Hdrs],
    process_results(Result);
parse(Data, Hdrs) ->
    case erlang:decode_packet(httph, Data, []) of
        {ok, http_eoh, Rest} ->
            parse(Rest, Hdrs);
        {ok, Hdr, Rest} ->
            parse(Rest, [Hdr|Hdrs]);
        Error ->
            Error
    end.

该parse/1函数最初使用line解码器对输入的第一行进行解码，并将结果传递给parse/2。第一个子句parse/2匹配"SPAMD/"输入数据的初始行的前缀只是为了验证我们在正确的位置，然后递归调用parse/2传递剩余的Data和空的累加器列表。的第二个和第三个子句parse/2将数据视为 HTTP 标头。parse/2输入数据耗尽时匹配的第二个子句；它将累积的头列表映射到一个{Key,Value}对列表，并将其传递给一个process_results/1函数，如下所述，以完成数据提取。parse/2尝试通过以下方式解码数据的第三个子句httphHTTP 标头解码器，累积每个匹配的标头并忽略http_eoh由"\r\n"嵌入在输入中奇数位置的序列产生的任何标头结束标记。

对于问题中提供的输入数据，parse/1,2函数最终将以下键值对列表传递给process_results/1：

[{'Content-Type',"multipart/mixed; boundary=\"----------=_5E10CA56.0200B819\""},{"Mime-Version","1.0"},{"X-Spam-Status","Yes, score=6.3 required=5.0 tests=BODY_SINGLE_WORD,\r\n\tDKIM_ADSP_NXDOMAIN,DOS_RCVD_IP_TWICE_C,HELO_MISC_IP,\r\n\tNO_FM_NAME_IP_HOSTN autolearn=no autolearn_force=no version=3.4.2"},{"X-Spam-Level","******"},{"X-Spam-Flag","YES"},{"X-Spam-Checker-Version","SpamAssassin 3.4.2 (2018-09-13) on\r\n\tdebpub1.cs2cloud.internal"},{"Message-Id","<3b68dede-f1c3-4f04-62dc-f0b2de6e980a@PPPPPP.local>"},{'Date',"Sat, 4 Jan 2020 18:24:36 +0100"},{"Subject","i"},{"To","<aZphki8N05@XXXXXXXX>"},{'From',"bibi <bibi@XXXXX.local>"},{"Received","from localhost by debpub1.cs2cloud.internal\r\n\twith SpamAssassin (version 3.4.2);\r\n\tSat, 04 Jan 2020 18:24:37 +0100"},{"Spam","True ; 6.3 / 5.0"},{'Content-Length',"728"}]

这些process_results/1,2函数首先匹配感兴趣的键，即"X-Spam-Status"，然后从其值中提取所需的数据。下面的三个函数实现process_results/1查找该键并对其进行处理，{error, not_found}如果没有看到该键则返回。第二个子句匹配所需的键，在空格、逗号、回车、换行符、制表符和等号字符上拆分其关联值，并将拆分结果与空累加器一起传递给process_results/2：

process_results([]) ->
    {error, not_found};
process_results([{"X-Spam-Status", V}|_]) ->
    process_results(string:lexemes(V, " ,\r\n\t="), []);
process_results([_|T]) ->
    process_results(T).

对于问题中的输入数据，传递给的字符串列表process_results/2是

["Yes","score","6.3","required","5.0","tests","BODY_SINGLE_WORD","\r\n","DKIM_ADSP_NXDOMAIN","DOS_RCVD_IP_TWICE_C","HELO_MISC_IP","\r\n","NO_FM_NAME_IP_HOSTN","autolearn","no","autolearn_force","no","version","3.4.2"]

下面的子句process_results/2递归地遍历这个字符串列表并累积匹配的结果。第二到第六个子句中的每一个都匹配我们寻找的一个值，并且每个子句在累加之前将匹配的字符串转换为二进制。

process_results([], Results) ->
    {ok, lists:reverse(Results)};
process_results([V="BODY_SINGLE_WORD"|T], Results) ->
    process_results(T, [list_to_binary(V)|Results]);
process_results([V="DKIM_ADSP_NXDOMAIN"|T], Results) ->
    process_results(T, [list_to_binary(V)|Results]);
process_results([V="DOS_RCVD_IP_TWICE_C"|T], Results) ->
    process_results(T, [list_to_binary(V)|Results]);
process_results([V="HELO_MISC_IP"|T], Results) ->
    process_results(T, [list_to_binary(V)|Results]);
process_results([V="NO_FM_NAME_IP_HOSTN"|T], Results) ->
    process_results(T, [list_to_binary(V)|Results]);
process_results([_|T], Results) ->
    process_results(T, Results).

最后一个子句忽略不需要的数据。process_results/2当字符串列表为空时调用的第一个子句，它只返回反向累加器。对于问题中的输入数据，最终结果process_results/2为：

{ok, [<<"BODY_SINGLE_WORD">>,<<"DKIM_ADSP_NXDOMAIN">>,<<"DOS_RCVD_IP_TWICE_C">>,<<"HELO_MISC_IP">>,<<"NO_FM_NAME_IP_HOSTN">>]}