fo：数据单元溢出

Question

fo：数据单元溢出

3 java xslt pdf-generation xsl-fo

我正在使用 XSLT -> FO 生成 PDF。

当一列中的文本超过该列的大小并且文本中没有空格时 - 则文本会进入下一个单元格或表格外。

我希望文本被占用在同一个单元格中。

提前致谢，Swetha

Answer 1

Jur*_*ris 5

您可以通过插入零宽度空格字符（U+200B，HTML 实体）将文本拆分为单词，那么这些位置会出现换行符：

<xsl:template name="split_value">
    <xsl:param name="value"/>
    <xsl:param name="max_length"/>
    <xsl:variable name="ret">
        <xsl:value-of select="substring($value, 1, $max_length)"/>
        <xsl:if test="string-length($value) &gt; $max_length">
            <xsl:value-of select="'&#x200b;'"/>
            <xsl:call-template name="split_value">
                <xsl:with-param
                    name="value"
                    select="substring($value, $max_length + 1)"
                />
                <xsl:with-param
                    name="max_length"
                    select="$max_length"
                />
            </xsl:call-template>
        </xsl:if>
    </xsl:variable>
    <xsl:value-of select="$ret"/>
</xsl:template>

Run Code Online (Sandbox Code Playgroud)

注意：您可能希望增强模板，使其仅拆分 $max_length 连续字符之间没有空格的文本片段。

这是一个测试用例。

输入 XML：

<data>0123456789</data>

Run Code Online (Sandbox Code Playgroud)

样式表（生成 HTML）：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    exclude-result-prefixes="xsl"
>
<xsl:template match="/">
    <html>
        <body
            style="font-family: Arial; font-size: 12pt; font-weight: normal"
        >
            <table width="4cm">
            <xsl:for-each select="/data">
                <tr><td>
                <xsl:call-template name="split_value">
                    <xsl:with-param
                        name="value"
                        select="text()"
                    />
                    <xsl:with-param
                        name="max_length"
                        select="number(4)"
                    />
                </xsl:call-template>
                </td>
                </tr>
            </xsl:for-each>
            </table>
        </body>
    </html>
</xsl:template>
</xsl:stylesheet>

Run Code Online (Sandbox Code Playgroud)

归档时间：	16 年，8 月前
查看次数：	1409 次
最近记录：	16 年，8 月前