cmake 2.8 自定义目标复制多个文件

Question

我被迫在 Linux 环境中使用较旧的 cmake 版本 2.8.12。

作为预构建步骤，我必须将多个头文件从源目录复制到目标目录。我决定使用该add_custom_target条款。如果这本身就是坏主意，请告诉我。例如：

add_custom_target( prebuild
  COMMENT "Prebuild step: copy other headers"
  COMMAND ${CMAKE_COMMAND} -E copy_if_different  ${CMAKE_SOURCE_DIR}/../other/include/alpha.h  ${CMAKE_SOURCE_DIR}/include/other
  COMMAND ${CMAKE_COMMAND} -E copy_if_different  ${CMAKE_SOURCE_DIR}/../other/include/bravo.h  ${CMAKE_SOURCE_DIR}/include/other
  COMMAND ${CMAKE_COMMAND} -E copy_if_different  ${CMAKE_SOURCE_DIR}/../other/include/charlie.h  ${CMAKE_SOURCE_DIR}/include/other
)

add_executable( myapp main.cxx )

# My application depends on the pre-build step.
add_dependencies( myapp prebuild )

set_target_properties( myapp PROPERTIES COMPILE_FLAGS "-g" )
install( TARGETS myapp DESTINATION ${BIN_INSTALL_DIR} )

列出每个头文件会很乏味。我知道如何搜索所有头文件并将它们放入列表变量中。例如。

file( GLOB other_headers "${CMAKE_SOURCE_DIR}/../other/include/*.h" )

但是，如何将该列表变量放在子句中使用add_custom_target？

有没有办法在子句中复制多个文件add_custom_target？

有没有更好的方法来复制多个文件作为预构建步骤，这些文件可以成为我的应用程序构建的依赖项？

受限于旧版本的 cmake 限制了我的选择。以下是我尝试过但没有成功的事情。

• 如果我有 cmake 版本 3.5，那么该copy_if_different命令可以采用多个源路径。
• 添加COMMAND_EXPAND_LISTS到该add_custom_target子句中没有任何作用。在更新的 cmake 版本之前，该功能必须不可用。
• foreach在子句中使用循环add_custom_target不起作用。在我见过的其他示例中，它们总是使用循环foreach，并且add_custom_target位于该循环内。但是，如果我这样做，那么我不知道如何使其成为我的应用程序构建的依赖项。

Answer 1

foreach在子句中使用循环add_custom_target不起作用。

通过使用，foreach您可以创建一个包含所有必需命令的变量。然后在中使用该变量add_custom_target：

set(commands)

# Assume 'other_headers' contain list of files
foreach(header ${other_headers})
  list(APPEND commands
    COMMAND ${CMAKE_COMMAND} -E copy_if_different ${header}  ${CMAKE_SOURCE_DIR}/include/other)
endforeach()

add_custom_target( prebuild
  COMMENT "Prebuild step: copy other headers"
  ${commands}
)