我如何在delphi控制台应用程序中实现IsKeyPressed函数？

Question

我有一个delphi控制台应用程序,我需要在用户按任意键时终止,问题是我不知道如何实现一个功能来检测按键何时,我想这样做.

{$APPTYPE CONSOLE}

begin
 MyTask:=MyTask.Create;
 try
 MyTask.RunIt; 
  while MyTask.Running and not IsKeyPressed do //how i can implement a IsKeyPressed  function?
    MyTask.SendSignal($56100AA);
 finally
   MyTask.Stop;
   MyTask.Free;
 end;

结束.

Answer 1

您可以编写一个函数来检测是否按下了一个键来检查console input buffer.

每个控制台都有一个输入缓冲区,其中包含一个输入事件记录队列.当控制台的窗口具有键盘焦点时,控制台将每个输入事件(例如单击键,鼠标移动或鼠标按键单击)格式化为它放置在控制台输入缓冲区中的输入记录.

首先,你必须调用GetNumberOfConsoleInputEvents函数来获取事件的数量,然后使用检索事件PeekConsoleInput功能,并检查事件是KEY_EVENT使用最后刷新控制台输入缓冲区FlushConsoleInputBuffer.

检查此样本

function KeyPressed:Boolean;
var
  lpNumberOfEvents     : DWORD;
  lpBuffer             : TInputRecord;
  lpNumberOfEventsRead : DWORD;
  nStdHandle           : THandle;
begin
  Result:=false;
  //get the console handle
  nStdHandle := GetStdHandle(STD_INPUT_HANDLE);
  lpNumberOfEvents:=0;
  //get the number of events
  GetNumberOfConsoleInputEvents(nStdHandle,lpNumberOfEvents);
  if lpNumberOfEvents<> 0 then
  begin
    //retrieve the event
    PeekConsoleInput(nStdHandle,lpBuffer,1,lpNumberOfEventsRead);
    if lpNumberOfEventsRead <> 0 then
    begin
      if lpBuffer.EventType = KEY_EVENT then //is a Keyboard event?
      begin
        if lpBuffer.Event.KeyEvent.bKeyDown then //the key was pressed?
          Result:=true
        else
          FlushConsoleInputBuffer(nStdHandle); //flush the buffer
      end
      else
      FlushConsoleInputBuffer(nStdHandle);//flush the buffer
    end;
  end;
end;