如何在xquery中格式化小数？

Question

我正在尝试在XQuery中格式化小数.小数是货币,因此格式应该是,###.##.

例如:

5573652.23 应该 5,573,652.23

和

352769应该352,769(或者352,769.00如果它更容易/更清洁)

现在我正在使用http://www.xqueryhacker.com/2009/09/format-number-in-xquery/中的这个函数,但我不能用它来使用小数:

declare function local:format-int($i as xs:int) as xs:string
{
  let $input :=
    if ($i lt 0) then fn:substring(fn:string($i), 2)
    else fn:string($i)
  let $rev := fn:reverse(fn:string-to-codepoints(fn:string($input)))
  let $comma := fn:string-to-codepoints(',')

  let $chars :=
    for $c at $i in $rev
    return (
      $c,
      if ($i mod 3 eq 0 and fn:not($i eq count($rev)))
      then $comma else ()
    )

  return fn:concat(
    if ($i lt 0) then '-' else (),
    fn:codepoints-to-string(fn:reverse($chars))
  )
};

我正在使用Saxon 9HE作为我的处理器.

任何帮助将不胜感激.

-----更新-----

基于Dimitre的回答,我修改了函数以保存小数部分并将其添加到返回字符串的末尾.

新功能

declare function local:format-dec($i as xs:decimal) as xs:string
{
  let $input := tokenize(string(abs($i)),'\.')[1]
  let $dec := substring(tokenize(string($i),'\.')[2],1,2)
  let $rev := reverse(string-to-codepoints(string($input)))
  let $comma := string-to-codepoints(',')

  let $chars :=
    for $c at $i in $rev
    return (
      $c,
      if ($i mod 3 eq 0 and not($i eq count($rev)))
      then $comma else ()
    )

  return concat(if ($i lt 0) then '-' else (),
                codepoints-to-string(reverse($chars)),
                if ($dec != '') then concat('.',$dec) else ()
                )
};

Answer 1

使用：

let $n := 5573652.23
 return
      concat(local:format-int(xs:int(floor($n))),
             '.',
             substring(string($n - floor($n)), 3)
             )

这会产生完全想要的正确结果：

5,573,652.23