OR 在 Open Policy Agent（联合行为）中

Question

在 OPA 中，很清楚如何查询condition AND condition：

values := {
  "value1": {
    "a": "one"
  },
  "value2": {
    "a": "one",
    "b": "two"
  },
  "value3": {
    "a": "one",
    "b": "one"
  }
}

goodValues = [name |
  value = values[name]
  value.a == "one"
  value.b == "one"
]

所以goodValues这里将value3只包含。

但是如何查询condition OR condition，以便goodValues将包含所有 3 个值，因为它们具有value.a == "one"OR value.b == "one"？

Answer 1

将多个表达式连接在一起表示逻辑 AND。要表达逻辑 OR，您可以定义多个具有相同名称的规则或函数。这有几种不同的工作方式。这在 OPA 的介绍中有介绍：https : //www.openpolicyagent.org/docs/latest/#logical-or。

选项 1：理解和函数

您要针对该值表达的条件可以分解为辅助函数，然后理解查询可以引用该函数。

goodValues = [name |
  value := values[name]
  value_match(value)
]

value_match(v) {
  v.a == "one"
}

value_match(v) {
  v.b = "two"
}

选项 2：增量规则

在 OPA/Rego 中，增量规则为变量分配一组值。规则定义提供了生成设置值的逻辑。与理解不同，您可以重载规则定义（提供多个同名）并像其他答案解释的那样表达逻辑 OR。

# goodValues is a set that contains 'name' if...
goodValues[name] {
 value := values[name]  # name is in values
 value.a == "one"       # value.a is "one"
}

# goodvalues is a set that contains 'name' if...
goodValues[name] {
  value := values[name]  # name is in values
  value.b == "two"       # value.b is "two"
}