在使用 for_each 创建的资源内包含 for_each 的动态块

Question

我正在尝试使用 Terraform 0.12+ 及其新的 for_each 在 Azure 中构建多个 vnet，但遇到了一些麻烦。我希望新功能能够让我创建一个接受复杂变量的通用网络模块，但我可能已经达到了它的极限，或者只是没有正确地思考它。本质上我的变量是这样构建的

variable "networks" {
  type = list(object({ name = string, newbits = number, netnum = number, subnets = list(object({ name = string, newbits = number, netnum = number}))}))
}

您可以看到它是一个网络数组，其中包含该网络的子网子数组。这样做可以轻松记录网络，而无需额外的 terraform 资源需求，因此我们的网络团队可以轻松调整/扩展，而无需担心了解 HCL。

我可以使用计数及其索引执行构建多个 vnet 资源的必要功能，但我想使用 for_each，因为它允许对键进行索引，而不是可能随时间变化的计数（需要重新部署，而我们不能做）。

网络对象

networks = [
    {
        # x.x.1.0/24
        name        = "DMZ",
        newbits     = "8",
        netnum      = "1",
        subnets      = [
            {
                # x.x.1.0/25
                name        = "DMZ"
                newbits     = "9",
                netnum      = "2"
            }
        ]
    },
    {
        # x.x.33.0/24
        name        = "Intermediary"
        newbits     = "8",
        netnum      = "33",
        subnets          = [
            {
                # x.x.33.0/25
                name        = "subnet1"
                newbits     = "9",
                netnum      = "66"
            },
            {
                # x.x.33.128/25
                name        = "subnet2"
                newbits     = "9",
                netnum      = "67"
            }
        ]
    }
]

我尝试并成功地使用 for_each 构建了 vnet，方法是将对象更改为映射，然后使用each.key 和each.value（为each.value 执行cidrsubnet），但问题在于创建子网。

locals {
    vnets = {
        for vnet in var.networks:
        vnet.name => cidrsubnet(var.root_cidr, vnet.newbits, vnet.netnum)
    }
}

由于地图不包括这些子网，所以我只是用头撞墙。有没有人有什么建议？或者我真的在不需要的时候让这个变得过于复杂？

资源创建有效，但没有子网

resource "azurerm_virtual_network" "vnets" {
  for_each            = local.vnets
  name                = each.key
  address_space       = [each.value]
  location            = azurerm_resource_group.network.location
  resource_group_name = azurerm_resource_group.network.name
}

我希望我可以使用动态块，并可能对其进行过滤以匹配网络资源内部的each.key。之后我也尝试使用自己的子网资源来完成此操作，但只是无法弄清楚。

这是我希望有用的全部资源

resource "azurerm_virtual_network" "vnets" {
  for_each            = local.vnets
  name                = "99999-Nucleus-${each.key}"
  address_space       = [each.value]
  location            = azurerm_resource_group.network.location
  resource_group_name = azurerm_resource_group.network.name

  dynamic "subnet" {
      for_each = [for vnet in var.networks:
      [for s in vnet.subnets: {
      name   = s.name
      prefix = cidrsubnet(var.root_cidr, s.newbits, s.netnum)
    }] if var.networks.name == each.key]

    content {
      name           = subnet.value.name
      address_prefix = subnet.value.prefix
    }
  }
}

Answer 1

在这里构建这个中间local.vnets映射会使这个问题更难解决，因为它丢弃了这些对象中的所有其他信息，从而使得很难使用块内的其他信息resource "azurerm_virtual_network" "vnets"。

相反，如果我们对原始var.networks值使用重复，那么我们可以subnets直接从内部获取列表each.value：

resource "azurerm_virtual_network" "vnets" {
  for_each = { for n in var.networks : n.name => n }

  location            = azurerm_resource_group.network.location
  resource_group_name = azurerm_resource_group.network.name

  name = "99999-Nucleus-${each.key}"
  address_space = [cidrsubnet(var.root_cidr, each.value.newbits, each.value.netnum)]

  dynamic "subnet" {
    for_each = each.value.subnets
    content {
      name           = subnet.value.name
      address_prefix = cidrsubnet(var.root_cidr, subnet.value.newbits, subnet.value.netnum)
    }
  }
}