基于声明性管道中前一阶段结果的条件执行

Question

我的管道设置如下。

我需要让它在遵守以下条件的情况下工作。帮助我定义何时使用块和其他代码以及在哪个阶段使用？

1. 如果 A 失败，则不会执行其他阶段，并且作业运行被标记为失败。
2. 如果任何 B 阶段失败，则不应调用相应的 C 阶段。
3. 当 C1 或 C2 被执行时，阶段 D 应该被执行，而不管它们的执行是否失败。
4. 此外，如果任何阶段失败，则整个作业运行状态应为失败。

我尝试并观察到了什么？ 从上面定义的条件来看，1 和 2 按预期工作，但在我的以下尝试中没有 3 和 4。

在C1和C2，我加了catchError(buildResult: 'SUCCESS', stageResult: 'FAILURE')指继续詹金斯管道失败过舞台。

但我观察到的是——

1. 如果 C1 或 C2 失败，则 D 执行，但所有作业运行都标记为成功。预期是失败，因为其中一个 C 步骤失败了。但由于捕获它获得成功状态。
2. 当任何 B 阶段失败时，它们对应的 C 也不会执行（预期），但也不会触发 D。因为我需要触发 D，因为已经执行了其他一些 C。

Answer 1

这是你需要的：

stageResultMap = [:]

pipeline {
    agent any
    stages {
        stage('A') {
            steps {
                println("This is stage: ${STAGE_NAME}")
            }
        }
        stage('BC') {
            parallel {
                stage ('1'){
                    stages {
                        stage('B1') {
                            steps {
                                script {
                                    // Catch exceptions, set the stage result as unstable,
                                    // build result as failure, and the variable didB1Succeed to false
                                    try {                                        
                                        sh "exit 1"
                                        stageResultMap.didB1Succeed = true
                                    }
                                    catch (Exception e) {
                                        unstable("${STAGE_NAME} failed!")
                                        currentBuild.result = 'FAILURE'
                                        stageResultMap.didB1Succeed = false                                        
                                    }
                                }
                            }
                        }
                        stage('C1') {
                            // Execute only if B1 succeeded
                            when {
                                expression {
                                    return stageResultMap.find{ it.key == "didB1Succeed" }?.value
                                }
                            }
                            steps {
                                // Mark the stage and build results as failure on error but continue pipeline execution
                                catchError(buildResult: 'FAILURE', stageResult: 'FAILURE') {
                                    sh "echo Hello"
                                }
                            }
                        }
                    } 
                }
                stage ('2'){
                    stages {
                        stage('B2') {
                            steps {
                                script {
                                    // Catch exceptions, set the stage result as unstable,
                                    // build result as failure, and the variable didB2Succeed to false
                                    try {
                                        sh "echo Hello"
                                        stageResultMap.didB2Succeed = true
                                    }
                                    catch (Exception e) {
                                        unstable("${STAGE_NAME} failed!")
                                        currentBuild.result = 'FAILURE'
                                        stageResultMap.didB2Succeed = false                                        
                                    }
                                }
                            }
                        }
                        stage('C2') {
                            // Execute only if B2 succeeded
                            when {
                                expression {
                                    return stageResultMap.find{ it.key == "didB2Succeed" }?.value
                                }
                            }
                            steps {
                                // Mark the stage and build results as failure on error but continue pipeline execution
                                catchError(buildResult: 'FAILURE', stageResult: 'FAILURE') {
                                    sh "echo Hello"
                                }
                            }
                        }
                    } 
                }
            }
        }
        stage('D') {
            // Execute only when C1 or C2 have executed, that is B1 or B2 have succeeded
            when {
                expression {
                    return stageResultMap.any {it.value}
                }
            }
            steps {
                println("This is stage: ${STAGE_NAME}")
            }
        }
    }
}

1. 对于阶段 C1 和 C2，用于catchError(buildResult: 'FAILURE', stageResult: 'FAILURE')将阶段和构建结果标记为 FAILURE 但继续管道执行。

2. 对于阶段 B1 和 B2，首先stageResultMap = [:]在 Jenkinsfile 顶部初始化一个空映射以捕获每个阶段的结果。现在，对于每个Bn阶段，使用一个try-catch块，以便在成功时将唯一的键值对stageResultsMap.didBnSucceed = true添加到映射中，并且在异常情况下，阶段结果设置为 UNSTABLE，构建结果设置为 FAILURE，然后stageResultsMap.didBnSucceed = false。我们在unstable这里使用该方法是因为没有其他两种方法catchError或warnError让我们添加到地图中。然后，在相应的 Cn 阶段，评估映射并仅在 Bn 成功时才执行。此外，如果 B1 和 B2 都失败，即 C1 和 C2 都没有执行，D 也不会执行，因为when {expression {return stageResultMap.any {it.value}}}将评估为false。但是，如果 C1 或 C2 执行而不管失败，D 都会执行。

在上述两种情况下，如果任何阶段失败，整体构建状态将被标记为 FAILURE。

当然，绿色构建没有失败。