使用 Terraform 的 CloudWatch 指标警报

Question

当尝试使用 Terraform 设置某些 CloudWatch 警报时，由于某种原因，它找不到指标，并且警报仍然陷入数据不足的状态。Terraform 不会输出任何错误，如果我在 AWS 中手动搜索，我可以找到指标。我在这里缺少什么？

指向目标组的简单健康主机警报示例：

#healthy host alarm
resource "aws_cloudwatch_metric_alarm" "health" {
  alarm_name          = "${var.tag_app}_healthy_host"
  comparison_operator = "LessThanThreshold"
  evaluation_periods  = "1"
  metric_name         = "HealthyHostCount"
  namespace           = "AWS/ApplicationELB"
  period              = "60"
  statistic           = "Maximum"
  threshold           = "1"
  alarm_description   = "Healthy host count for EC2 machine"
  alarm_actions       = ["${data.aws_sns_topic.blabla.arn}"]
  ok_actions          = ["${data.aws_sns_topic.blabla.arn}"]

  dimensions = {
    TargetGroup  = "${aws_lb_target_group.alb_target.arn_suffix}"
  }
}

当我选择另一个资源（EC2、RDS）和另一个指标时，我会收到指向正确指标的 CloudWatch 警报，并且它不会陷入数据不足的困境。

Answer 1

该HealthyHostCount指标TargetGroup, LoadBalancer仅在维度或维度下可用，TargetGroup, AvailabilityZone, LoadBalancer因此您至少还需要添加LoadBalancer维度才能访问此指标。

所以你的 Terraform 代码应该是：

#healthy host alarm
resource "aws_cloudwatch_metric_alarm" "health" {
  alarm_name          = "${var.tag_app}_healthy_host"
  comparison_operator = "LessThanThreshold"
  evaluation_periods  = "1"
  metric_name         = "HealthyHostCount"
  namespace           = "AWS/ApplicationELB"
  period              = "60"
  statistic           = "Maximum"
  threshold           = "1"
  alarm_description   = "Healthy host count for EC2 machine"
  alarm_actions       = ["${data.aws_sns_topic.blabla.arn}"]
  ok_actions          = ["${data.aws_sns_topic.blabla.arn}"]

  dimensions = {
    LoadBalancer = "${aws_lb.example.arn_suffix}"
    TargetGroup  = "${aws_lb_target_group.alb_target.arn_suffix}"
  }
}