如何从存储过程中获取唯一标识符？

Question

我觉得我是如此亲密，我似乎无法弄清楚如何使用存储过程从SQL Server获取GUID。它没有返回值，或者没有以正确的方式调用输出。

看了两天的文档后，我想到的是：

DROP PROCEDURE IF EXISTS create_product
GO

CREATE PROCEDURE create_product 
    (@Name VARCHAR(255),
     @Price DOUBLE PRECISION,
     @Image VARCHAR(255),
     @Free_Shipping BIT,
     @Description VARCHAR(MAX),
     @Shipping_Id UNIQUEIDENTIFIER,
     @PRODUCT_ID UNIQUEIDENTIFIER OUTPUT)
AS
    SELECT @PRODUCT_ID = NEWID();

    DECLARE @PRODUCT_DETAIL_ID UNIQUEIDENTIFIER;
    SET @PRODUCT_DETAIL_ID = NEWID();

    INSERT INTO Product (product_id, product_name, product_price, product_image,
                         product_free_shipping, product_detail_id) 
    VALUES (@PRODUCT_ID, @Name, @Price, @Image,
            @Free_Shipping, NULL);

    INSERT INTO ProductDetail (detail_id, detail_description, detail_product_id,
                               detail_product_meta_id, detail_shipping_id)
    VALUES (@PRODUCT_DETAIL_ID, @Description, @PRODUCT_ID,
            NULL, @Shipping_Id);

    UPDATE Product
    SET product_detail_id = @PRODUCT_DETAIL_ID
    WHERE product_id = @PRODUCT_ID;

    PRINT @PRODUCT_ID
GO

DECLARE @PID UNIQUEIDENTIFIER;

EXEC create_product 'Name8', 10.79, 'Image8', 0, 'Description of the eigth', '0511DE6D-F448-471D-B1B2-11C19E991927', @PID OUTPUT
GO

PRINT @PID

我仅PRINT在末尾添加了用于调试目的，以确保确实设置了我的值。我得到的错误是：

消息137，级别15，状态2，第60行
必须声明标量变量“ @PID”。

这看起来很奇怪

Answer 1

变量的作用域是批处理，GO是批处理分隔符。去掉它。

DECLARE @PID UNIQUEIDENTIFIER;
EXEC create_product 'Name8', 10.79, 'Image8', 0, 'Description of the eigth', '0511DE6D-F448-471D-B1B2-11C19E991927', @PID OUTPUT
PRINT @PID