什么是从bitmapData获取jpg的最简单方法

Question

我需要将从影片剪辑中抓取的bitmapData转换为jpeg或png.是否有一些lib？

Answer 1

在将字节转换为图像的take部分中看到此示例,我已经给出了整体供您参考

package {
    import encoding.JPGEncoder;
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.utils.ByteArray;
    import flash.events.Event

    public class Converter extends Sprite {

        [Embed(source = "image.jpg")]
        private var image:Class

        private const QUALITY:uint = 80;

        public function Converter():void {

            var bitmap:Bitmap = new image();
            var bitmapData:BitmapData = bitmap.bitmapData;

            //encode BitmapData to JPG 
            var encoder:JPGEncoder = new JPGEncoder(QUALITY);
            var rawBytes:ByteArray = encoder.encode(bitmap.bitmapData);

            //decode JPG ByteArray back to BitmapData
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, getBitmapData)
            loader.loadBytes(rawBytes); 
        }

        private function getBitmapData(e:Event):void  {
            var decodedBitmapData:BitmapData = Bitmap(e.target.content).bitmapData
            trace(decodedBitmapData);
        }
    }   
}

Answer 2

您现在可以使用Flash Player 11.3和AIR 3.3中内置的本机jpeg编码.

var quality:int = 50;
var bounds:Rectangle = bitmapData.rect;
var result:ByteArray = bitmapData.encode(bounds, new JPEGEncoderOptions(50));

这需要-swf-version=16传递给编译器.