在 Terraform 0.12 中连接两个列表 - concat()

Question

我想在 Terraform 0.12 中连接两个数组。在我的示例中，有公共和私有子网。我想将它们分配给相同的网络访问列表。以下代码缩短：

data "aws_subnet_ids" "private" {
    vpc_id = aws_vpc.main.id
    tags = {
        subnet-type  = "private"
    }
}

data "aws_subnet_ids" "public" {
    vpc_id = aws_vpc.main.id
    tags = {
        subnet-type  = "public"
    }
}


resource "aws_network_acl" "networks" {
    vpc_id = aws_vpc.main.id

    subnet_ids = concat(data.aws_subnet_ids.private.ids, data.aws_subnet_ids.public.ids)
    [...]
}

如果我使用以下输出：

output "private_subnets" {
  value = data.aws_subnet_ids.private.ids
}

output "public_subnets" {
  value = data.aws_subnet_ids.public.ids
}

生成以下输出：

private_subnets = [
  "subnet-243zr427rhhfjseb9",
  "subnet-we789rh2438fchb6e",
  "subnet-092rz7g82fhhkui74",
]
public_subnets = [
  "subnet-12230qegvg764e9d",
  "subnet-123465svgvgf0d7e",
]

所以一切都应该有效。但是给出了以下错误：

iptizer@machine:~/src/infra$ terraform12 apply
[...]

Error: Invalid function argument

  on nacls.tf line 19, in resource "aws_network_acl" "networks":
  19:     subnet_ids = concat(data.aws_subnet_ids.private.ids, data.aws_subnet_ids.public.ids)
    |----------------
    | data.aws_subnet_ids.private.ids is set of string with 3 elements

Invalid value for "seqs" parameter: all arguments must be lists or tuples; got
set of string.

Bug .. 或者我错过了什么？

Answer 1

Terraform 0.12 比 0.11 更能区分列表和集合值，并包括一些像这样的额外检查。

在这种特殊情况下，concat以这种方式失败，因为串联要求所有元素都具有明确定义的顺序，以便结果也可以具有明确定义的顺序。集合没有排序，所以这个检查是为了提醒您在转换为列表时明确选择合适的排序，或者根本不转换为列表。

在这种特殊情况下，排序似乎并不是特别重要，因此实现的词法排序sort可能就足够了：

  subnet_ids = concat(
    sort(data.aws_subnet_ids.private.ids),
    sort(data.aws_subnet_ids.public.ids),
  )

（因为从字符串列表集到字符串列表的转换也强加了词法顺序，这在功能上等同tolist于字符串集。我通常更喜欢sort这里，因为它是未来读者的一个线索，即结果将按词法顺序排列。）

另一种选择是在集合的世界中说，并使用setunion：

  subnet_ids = setunion(
    data.aws_subnet_ids.private.ids,
    data.aws_subnet_ids.public.ids,
  )

由于这两个列表之间不应有重复项，因此您在此处使用哪种方法并不重要，但为了完整起见，我会注意到，如果这两个列表都包含相同的子网 ID，则setunion操作将对它们进行重复数据删除，因为每个唯一值在一组中只能出现零次或一次。

在我写这篇文章的时候， wherecount仍然是为集合中的每个项目创建一个资源实例的主要方式，通常最终需要转换为列表，以便单个实例可以具有所需的顺序。一旦for_each实现，在这样的情况下使用集合而不是列表会有一个优势：

resource "aws_instance" "per_subnet_example" {
  # resource-level for_each is not implemented at the time of writing,
  # but planned for a future release.
  for_each = setunion(
    data.aws_subnet_ids.private.ids,
    data.aws_subnet_ids.public.ids,
  )

  # ...
}

当使用for_each集合而不是 时count，Terraform 将通过集合中的值而不是连续索引来标识每个实例，因此该资源中的一个实例可能具有地址aws_instance.per_subnet_example["subnet-abc123"]，这意味着当元素从该集合中添加和删除时可以只创建/销毁相应的单个实例，而不是在有序序列更改后可能重新创建所有内容。

Terraform 提供者在有意义的地方使用这样的集合，以便在这种for_each模式到达后更容易使用，但不幸的是，这意味着我们需要同时编写一些额外的显式类型转换，以便明确我们'以类似序列的方式而不是类似集合的方式重新处理这些值。

Answer 2

在 terraform-providers/terraform-provider-aws 问题中已经报告了类似的问题。

https://github.com/terraform-providers/terraform-provider-aws/issues/7522

并且还提到了同样的解决方法。对于您的情况，您可以像下面这样解决

解决方法#1

locals {                                                            
  private_subnet_ids_string = join(",", data.aws_subnet_ids.private.ids)
  private_subnet_ids_list = split(",", local.private_subnet_ids_string)
  public_subnet_ids_string = join(",", data.aws_subnet_ids.public.ids)
  public_subnet_ids_list = split(",", local.public_subnet_ids_string)             
}

resource "aws_network_acl" "networks" {
    vpc_id = aws_vpc.main.id

    subnet_ids = concat(local.private_subnet_ids_list, local.public_subnet_ids_list)
    [...]
}

解决方法＃2

resource "aws_network_acl" "networks" {
    vpc_id = aws_vpc.main.id

    subnet_ids = concat(tolist(data.aws_subnet_ids.private.ids), tolist(data.aws_subnet_ids.public.ids))
    [...]
}