如何使用 Cmake 用 NASM 构建二进制文件

Question

我正在学习 x64 并且我讨厌 make，所以我试图让 cmake 使用 NASM 构建二进制文件。

cmake 大致支持这一点，但文档很垃圾。这就是我现在所做的工作，将堆栈溢出中的内容拼凑在一起，然后删除不会破坏构建的所有内容：

cmake_minimum_required(VERSION 3.14)

set(CMAKE_ASM_NASM_LINK_EXECUTABLE "ld <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>")
set(CMAKE_ASM_NASM_OBJECT_FORMAT elf64)

project(test_project ASM_NASM)

set_source_files_properties(test.s PROPERTIES LANGUAGE ASM_NASM)
add_executable(test test.s)
if(CMAKE_BUILD_TYPE STREQUAL "Debug")
    target_compile_options(test PRIVATE -g -Fdwarf)
endif()

所以有几个问题，为什么我必须告诉 cmake 使用ld链接，有没有更好的方法来做到这一点？

有什么target_object_format可以用来指定对象格式而不是全局设置的内容吗？

有没有办法让 cmake 识别新的扩展名，而不是专门告诉它每个文件是 ASM_NASM？

Answer 1

查看源代码，ASM 构建仅由这组文档记录不佳的环境变量控制。

Michael 正确地指出，默认情况下，CMAKE_ASM_LINK_EXECUTABLE定义为：

<CMAKE_ASM_NASM_COMPILER> <FLAGS> <CMAKE_ASM_NASM_LINK_FLAGS> <LINK_FLAGS> <OBJECTS>  -o <TARGET> <LINK_LIBRARIES>

这感觉像是一个错误，因为nasm不进行链接并且没有记录您需要更改此环境变量。所以要使用ld我们需要设置：

set(CMAKE_ASM_NASM_LINK_EXECUTABLE "ld <CMAKE_ASM_NASM_LINK_FLAGS> <LINK_FLAGS> <OBJECTS>  -o <TARGET> <LINK_LIBRARIES>")

接下来是源文件扩展名，默认情况下cmake 只识别.asm和.nasm. 如果我们想扩展它，我们可以通过使用关联的环境变量来实现：

set(CMAKE_ASM_NASM_SOURCE_FILE_EXTENSIONS ${CMAKE_ASM_NASM_SOURCE_FILE_EXTENSIONS} s S)

最后是对象格式，不幸的是这也由环境变量控制，因此我们可以使用以下方法全局更改它：

set(CMAKE_ASM_NASM_OBJECT_FORMAT elf64)

或者我们可以通过重新定义CMAKE_ASM_NASM_COMPILE_OBJECT和创建我们自己的属性来获得更细粒度的控制（我不明白为什么这不是由 cmake 自己完成的）：

enable_language(ASM_NASM)
set(CMAKE_ASM_NASM_COMPILE_OBJECT "<CMAKE_ASM_NASM_COMPILER> <INCLUDES> <FLAGS> -o <OBJECT> <SOURCE>")

# Create a compile option that operates on ASM_NASM files
# If the target has a property NASM_OBJ_FORMAT, use it, otherwise
# use the environment variable CMAKE_ASM_NASM_OBJECT_FORMAT
add_compile_options(
    "$<$<COMPILE_LANGUAGE:ASM_NASM>:-f $<IF:$<BOOL:$<TARGET_PROPERTY:NASM_OBJ_FORMAT>>, \
    $<TARGET_PROPERTY:NASM_OBJ_FORMAT>, ${CMAKE_ASM_NASM_OBJECT_FORMAT}>>"
)


add_executable(test test.S)
set_target_properties(test PROPERTIES NASM_OBJ_FORMAT elf64)

向CMake 3.15前，每次启用ASM_NASM通过enable_language()或project()将会覆盖CMAKE_ASM_NASM_COMPILE_OBJECT。在 3.15 以上的版本中，enable_language()不需要调用并且可以在project().

奖金，CMAKE_ASM_NASM_FLAGS_DEBUG默认情况下是空的，所以请随意将其设置为理智的：

set(CMAKE_ASM_NASM_FLAGS_DEBUG "-g -Fdwarf")

老实说，cmake 中的 ASM 支持似乎是半生不熟的。它显然比 Make 或 Automake 更好，但并不像您希望的那样顺利地支持“现代”cmake 的习语。