在 Terraform 中迭代列表或元素集的问题

Question

我正在尝试在子网 ID 列表上使用计数变量在跨可用区创建的不同子网中启动 AWS 实例，但它失败并显示不同方法的错误消息。

我试过使用 element() 和 [count.index]，我使用的是 TF v12。

下面是代码片段，请忽略带有#(commented) 的行。

resource "aws_instance" "workers" {
#count         =   length(data.terraform_remote_state.network.outputs.public_subnet_list)
count         = length(data.aws_subnet_ids.subnet_list.ids)
instance_type = var.worker_instance_type
ami           = var.k8_ami
key_name      = aws_key_pair.ssh_key.key_name
#subnet_id     = "${data.terraform_remote_state.network.outputs.public_subnet_list[count.index]}"
subnet_id = "${element(data.aws_subnet_ids.subnet_list.ids, count.index)}"
vpc_security_group_ids = [
aws_security_group.kubernetes.id
]
}

下面是两个错误片段。

Error: Invalid index

on k8-cluster.tf line 85, in resource "aws_instance" "workers":
85:   subnet_id = "${data.aws_subnet_ids.subnet_list.ids[count.index]}"
|----------------
| count.index is 2
| data.aws_subnet_ids.subnet_list.ids is set of string with 4 elements

This value does not have any indices.

element() 的另一个错误：

Error: Error in function call

on k8-cluster.tf line 85, in resource "aws_instance" "workers":
85:   subnet_id = "${element(data.aws_subnet_ids.subnet_list.ids, count.index)}"
|----------------
| count.index is 3
| data.aws_subnet_ids.subnet_list.ids is set of string with 4 elements

Call to function "element" failed: cannot read elements from set of string.

Answer 1

这里的根本问题是它data.aws_subnet_ids.subnet_list.ids是一个集合值，而不是一个列表值，因此它的元素没有特定的顺序，因此不能通过数字索引访问列表。

要将其用作列表，需要决定如何对元素进行排序。在这种情况下，排序似乎并不重要，因为目标只是为每个子网创建一个实例，因此将集合传递给sort函数应该足以对它们进行词法排序：

resource "aws_instance" "workers" {
  count         = length(data.terraform_remote_state.network.outputs.public_subnet_list)
  instance_type = var.worker_instance_type
  ami           = var.k8_ami
  key_name      = aws_key_pair.ssh_key.key_name
  subnet_id     = sort(data.terraform_remote_state.network.outputs.public_subnet_list)[count.index]
  vpc_security_group_ids = [
    aws_security_group.kubernetes.id
  ]
}

在 Terraform 的未来版本（在 v0.12.0 撰写本文时尚不可用）for_each中，计划了一项新功能，使这更简单：

resource "aws_instance" "workers" {
  # Planned for a future Terraform release; not in v0.12.0
  for_each = data.terraform_remote_state.network.outputs.public_subnet_list

  instance_type = var.worker_instance_type
  ami           = var.k8_ami
  key_name      = aws_key_pair.ssh_key.key_name
  subnet_id     = each.value
  vpc_security_group_ids = [
    aws_security_group.kubernetes.id
  ]
}

for_each一旦实现（除了简洁），它的一个优点是它还会告诉 Terraform 通过子网 id 字符串而不是列表中的位置来标识此资源的各个实例。这意味着将来添加新子网不会导致以后的实例“偏移”并不必要地重新创建，就像我上面的原始示例一样。

Answer 2

发生此问题是因为返回的数据采用“SET”的形式，而元素期待“LIST”形式的输入。

要解决此问题，您需要将其转换为列表。

subnet_id = "${element(tolist(data.aws_subnet_ids.subnet_list.ids), count.index)}"