为什么函数的return语句不是通常的int []

Question

我刚刚开始使用Dlang，对于想要更安全的C语言的人们来说，它似乎是理想的选择。此外，它还具有现代范例，例如函数式编程。

我正在尝试以下代码将数字列表作为字符串转换为整数列表：

import std.stdio; 
import std.array;
import std.conv;

int[] list_str2int(char[][] slist){     // this function should convert a list of numbers as char[] to integers
    int[100] intcol; 
    int N = cast(int)slist.length; 
    foreach(int i; 0..N){
        char[] temp = slist[i];
        temp = split(temp, ".")[0];   // effectively this is floor; to!int does not work if '.' is there; 
        intcol[i] = to!int(temp);   // not working; 
    }
    return intcol;                  // error from this statement; 
}

void main(){
    char[][] strlist = cast(char[][])["1.1","2.1","3.2","4.4"]; 
    int[] newintlist = list_str2int(strlist); 
    writeln("Converted list: ", newintlist); 
}

但是出现以下错误：

testing.d(13): Error: returning cast(int[])intcol escapes a reference to local variable intcol
Failed: ["/usr/bin/dmd", "-v", "-o-", "testing.d", "-I."]

我不明白为什么变量为int []的第一个函数的返回行上会有错误。

问题在哪里，如何解决？谢谢你的帮助。

Answer 1

int[100]是一个静态数组（值类型），位于list_str2int的堆栈框架上-因此一旦函数返回，它将不再存在。该函数的返回值int[]是一个切片（引用类型），它不保存任何数据，但引用内存中某个位置的连续整数。return intcol;因此，该语句占用了静态数组的一个切片，但是，返回该语句无效，因为该切片将指向该函数返回后将不再有效的内存。

您有几种选择：

• int[100]还要声明返回类型。将其设置为值类型后，整数将被复制到调用方的堆栈框架中。

• 通过将数组声明并初始化为，在程序堆中分配数组auto intcol = new int[100];。这将intcol在堆中占用一部分内存。堆中的内存归垃圾收集器所有，实际上具有无限的生命周期。

• 除了上述以外，但对于现代D而言更惯用的一种选择是使用范围。您的程序可以重写为单个语句，如下所示：

  import std.algorithm.iteration;
  import std.stdio; 
  import std.array;
  import std.conv;
  
  void main()
  {
      ["1.1", "2.1", "3.2", "4.4"]
          .map!(item => item
              .split(".")[0]
              .to!int
          )
          .array // optional, writeln and co can write ranges
          .writefln!"Converted list: %s";
  }