xslt仅在一个节点中替换\n？

Question

嘿,我有一个节点<msg>,其中包含一条消息

string1
string 2
sting3

但是当它呈现时,它呈现所有一行我怎么能用<br />替换所有\n.

我试过了

<xsl:value-of select ='replace(msg," ","<br />")'/>

但我得到这个错误

加载样式表时出错:无效的XSLT/XPath函数.

我该怎么做呢？

Answer 1

在要处理的字符串上调用此模板:

<xsl:template name="break">
  <xsl:param name="text" select="string(.)"/>
  <xsl:choose>
    <xsl:when test="contains($text, '&#xa;')">
      <xsl:value-of select="substring-before($text, '&#xa;')"/>
      <br/>
      <xsl:call-template name="break">
        <xsl:with-param 
          name="text" 
          select="substring-after($text, '&#xa;')"
        />
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$text"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

像这样(它将在当前节点上工作):

<xsl:template match="msg">
  <xsl:call-template name="break" />
</xsl:template>

或者像这样,显式传递一个参数:

<xsl:template match="someElement">
  <xsl:call-template name="break">
    <xsl:with-param name="text" select="msg" />
  </xsl:call-template>
</xsl:template>

我认为您正在使用XSLT 1.0处理器,而replace()是XSLT/XPath 2.0引入的函数.