检查调用时，模拟方法也会返回 null

Question

我不确定我是否滥用了基于交互的测试，或者我是否做了一些概念上错误的事情。我正在开发 Spring Boot 应用程序 (Kotlin)，我的测试使用 Spock/Groovy。

我有一个正在测试的类，它调用另一个服务来查询信息。被测试的类应该缓存结果。但是，我无法模拟具有返回值的方法并检查调用次数，因为一旦我添加调用检查，模拟的方法总是返回 null。

我创建了一个单独的示例来演示该问题。

这是正在测试的类：

@Service
class DemoService(private val downstreamService: DownstreamService) {
    fun demo(id: String): String {
        val something = downstreamService.something(id)
        return something
    }
}

正在使用此服务：

@Service
class DownstreamService {
    fun something(id: String): String {
        return id
    }
}

这就是我的测试的样子：

class DemoServiceTest extends Specification {
    def downStream = Mock(DownstreamService)
    def demoService = new DemoService(downStream)

    def "value check"() {
        given:
        def test = "my test string"
        downStream.something(test) >> "xxx"

        when:
        def actual = demoService.demo(test)

        then:
        actual == "xxx" // works
    }   

    def "invocation check"() {
        given:
        def test = "my test string"
        downStream.something(test) >> "xxx"

        when:
        demoService.demo(test)

        then:
        1 * downStream.something(test) // works
    }

    def "combined check"() {
        given:
        def test = "my test string"
        downStream.something(test) >> "xxx"

        when:
        def demo = demoService.demo(test)

        then:
        1 * downStream.something(test)
        demo == "xxx" // fails because demo is null
    }

}

前两个测试按预期工作，但最后一个测试失败，因为当我添加调用检查时返回值始终为 null。

Answer 1

将模拟与调用计数检查结合起来存在问题，因为此时并没有调用模拟。

您可以通过以下方式重写组合测试以使其正常工作：

def "combined check"() {
    given:
    def test = 'my test string'

    when:
    def demo = demoService.demo(test)

    then:
    1 * downStream.something(test) >> 'xxx'
    demo == 'xxx'
}