VBA：全局常量字符串

Question

我正在 Excel 中处理数学的特殊字符。
（指数？、GR？？K 和其他杂项 Unicode 字符。）

我想将常用的 Unicode 字符串存储为全局常量，因为这可能比CStr()每次需要时调用都要快得多（并且不易出错）。

例如，我在所有函数之外都有这些声明：

Public Const STRPOWER0        As String = CStr(ChrW(&H2070)) '0th power
Public Const STRPOWER1        As String = "¹" 'CStr(ChrW(&HB9)) 1st power
Public Const STRPOWER2        As String = "²" 'CStr(ChrW(&HB2)) 2nd power
Public Const STRPOWER3        As String = "³" 'CStr(ChrW(&HB3)) 3rd power
Public Const STRPOWER4        As String = CStr(ChrW(&H2074)) '4th power
Public Const STRPOWER5        As String = CStr(ChrW(&H2075)) '5th power
Public Const STRPOWER6        As String = CStr(ChrW(&H2076)) '6th power
Public Const STRPOWER7        As String = CStr(ChrW(&H2077)) '7th power
Public Const STRPOWER8        As String = CStr(ChrW(&H2078)) '8th power
Public Const STRPOWER9        As String = CStr(ChrW(&H2079)) '9th power
Public Const STRPOWERNEGATIVE As String = CStr(ChrW(&H207B)) 'Superscript negative sign

问题是，每当我尝试引用这些字符串之一时，值是Empty
（如果我打开，Option Explicit我会收到错误Variable not defined）

我究竟做错了什么？
VBA 不支持将全局常量作为字符串吗？

Answer 1

不幸的是，您不能使用函数将值设置为常量。a 的目的Const是在运行时之前设置常量的值，并且函数只能在运行时返回值。

您的问题似乎是您的常量未在模块的声明部分中声明，这就是为什么在运行任何代码时都不会出现编译错误的原因。

但是，有一些替代方案。

您可以为每个变量创建一个函数：

Function STRPOWER0() As String
    STRPOWER0 = CStr(ChrW(&H2070))
End Function

Sub Main()
    Msgbox STRPOWER0
End Sub

您指出每次调用 时都担心运行CStr()和ChrW()函数STRPOWER0。虽然您可能只会受到非常小的性能影响 - 即使多次调用 - 您也可以使用Static变量在运行时仅在第一次进行转换。

Function STRPOWER0() As String
    Static RetVal As String
    If RetVal = "" Then RetVal = CStr(ChrW(&H2070))
    STRPOWER0 = RetVal
End Function

Sub Main()
    Msgbox STRPOWER0
End Sub

静态允许变量RetVal在整个运行时期间保留其数据，即使函数超出范围也是如此。

另一种选择是使用 sub 在运行时开始时设置所有变量：

'This line in declarations section of module
Public STRPOWER0$, STRPOWER1$, STRPOWER2$ ', etc

Private Sub SetPubVars

    STRPOWER0 = CStr(ChrW(&H2070))
    STRPOWER1 = CStr(ChrW(&HB9))
    STRPOWER2 = CStr(ChrW(&HB2))

    ' So on

End Sub

Sub MAIN()

    ' Set the values
    SetPubVars

    MsgBox STRPOWER0

End Sub