Perl程序可以知道__DATA__开头的行号吗？

Question

有没有办法获取编码__DATA__令牌的行号（可能还有文件名）？或者以其他方式知道原始源文件中从DATA文件句柄读取的一行数据来自的实际行号？

请注意，$.从DATA文件句柄读取时从1开始计数。因此，如果将__DATA__令牌的行号添加到了$.它，那将是我正在寻找的东西。

例如：

#!/usr/bin/perl
while (<DATA>) {
  my $n = $. + WHAT??;
  die "Invalid data at line $n\n" if /bad/;
}

__DATA__
something good
something bad

我想说的是“第9行的数据无效”，而不是“第2行”（如果$.它本身被使用，这就是您得到的）。

Answer 1

在支持/proc/<pid>虚拟文件系统的系统（例如Linux）中，您可以执行以下操作：

# find the file where <DATA> handle is read from
my $DATA_FILE = readlink("/proc/$$/fd/" . fileno(*DATA));

# find the line where DATA begins
open my $THIS, "<", $DATA_FILE;
my @THIS = <$THIS>;
my ($DATA_LINE) = grep { $THIS[$_] =~ /^__DATA__\b/ } 0 .. $#THIS;

Answer 2

Perl 跟踪创建每个符号的文件和行。符号通常是在解析器/编译器第一次遇到它时创建的。但如果__DATA__之前遇到过DATA以其他方式创建的，则这将创建该符号。我们可以利用这一点来设置与文件句柄关联的行号DATA。

Package::DATA对于句柄本身不使用的情况，可以通过句柄上获取令牌Package.pm的行号：__DATA__B::GV->LINEDATA

$ cat Foo.pm
package Foo;

1;
__DATA__
good
bad

$ perl -I. -MFoo -MB -e '
   my $ln = B::svref_2object(\*Foo::DATA)->LINE;
   warn "__DATA__ at line $ln\n";
   Foo::DATA->input_line_number($ln);
   while(<Foo::DATA>){ die "no good" unless /good/ }
'
__DATA__ at line 4
no good at -e line 1, <DATA> line 6.

在文件本身引用句柄的情况下DATA，可能的组装方法是使用@INChook：

$ cat DH.pm
package DH;

unshift @INC, sub {
        my ($sub, $fname) = @_;
        for(@INC){
                if(open my $fh, '<', my $fpath = "$_/$fname"){
                        $INC{$fname} = $fpath;
                        return \'', $fh, sub {
                                our (%ln, %pos);
                                if($_){ $pos{$fname} += length; ++$ln{$fname} }
                        }
                }
        }
};

$ cat Bar.pm
package Bar;

print while <DATA>;

1;
__DATA__
good
bad

$ perl -I. -MDH -MBar -e '
    my $fn = "Bar.pm";
    warn "__DATA__ at line $DH::ln{$fn} pos $DH::pos{$fn}\n";
    seek Bar::DATA, $DH::pos{$fn}, 0;
    Bar::DATA->input_line_number($DH::ln{$fn});
    while (<Bar::DATA>){ die "no good" unless /good/ }
'
good
bad
__DATA__ at line 6 pos 47
no good at -e line 6, <DATA> line 8.

只是为了完成，在您确实可以控制文件的情况下，所有操作都可以轻松完成：

print "$.: $_" while <DATA>;
BEGIN { our $ln = __LINE__ + 1; DATA->input_line_number($ln) }
__DATA__
...

您还可以使用第一个B::GV解决方案，前提是您DATA通过以下方式引用句柄eval：

use B;
my ($ln, $data) = eval q{B::svref_2object(\*DATA)->LINE, \*DATA}; die $@ if $@;
$data->input_line_number($ln);
print "$.: $_" while <$data>;
__DATA__
...

这些解决方案都没有假定源文件是可查找的（除非您想DATA多次读取源文件，就像我在第二个示例中所做的那样），或者尝试重新解析您的文件等。