遍历 terraform 中的地图列表列表

Question

考虑我有一个变量，它是地图列表的列表。

例子：

    processes = [
      [
       {start_cmd: "a-server-start", attribute2:"type_a"}, 
       {start_cmd: "a-worker-start", attribute2:"type_b"}
       {start_cmd: "a--different-worker-start", attribute2:"type_c"}
      ],
      [
       {start_cmd: "b-server-start", attribute2:"type_a"},
       {start_cmd: "b-worker-start", attribute2:"type_b"}
      ]
    ]

在每次迭代中，我需要取出地图数组，然后遍历该数组并取出地图的值。我如何在 terraform 中实现这一目标？

我考虑过有两个计数并做一些算术来欺骗 terraform 执行相似的嵌套迭代检查参考here。但在我们的例子中，内部数组中的映射数量可能会有所不同。

此外，我们目前正在使用 0.11 terraform 版本，但不介意使用 alpha 0.12 版本的 terraform，如果可以在该版本中实现这一点。

编辑：

添加了我将如何使用此变量：

resource “create_application” “applications” {
  // Create a resource for every array in the variable processes. 2 in this case
  name        = ""              
  migration_command = "" 

  proc {                
    // For every map create this attribute for the resource.
    name    = ““                
    init_command   = “a-server-start”                   
    type   = “server”                
  }                                    
}                                      

不确定这是否清除了要求。如果还不清楚，请询问。

Answer 1

使用 terraform 0.12.x

locals {
  processes = [
    [
      { start_cmd: "a-server-start", type: "type_a", name: "inglorious bastards" },
      { start_cmd: "a-worker-start", type: "type_b", name: "kill bill" },
      { start_cmd: "a--different-worker-start", type: "type_c", name: "pulp fiction" },
    ],
    [
      { start_cmd: "b-server-start", type: "type_a", name: "inglorious bastards" },
      { start_cmd: "b-worker-start", type: "type_b", name: "kill bill" },
    ]
  ]
}

# just an example
data "archive_file" "applications" {
  count = length(local.processes)

  type = "zip"

  output_path = "applications.zip"

  dynamic "source" {
    for_each = local.processes[count.index]

    content {
      content  = source.value.type
      filename = source.value.name
    }
  }
}

$ terraform apply
data.archive_file.applications[0]: Refreshing state...
data.archive_file.applications[1]: Refreshing state...

Apply complete! Resources: 0 added, 0 changed, 0 destroyed.

如果create_application资源存在，则可以像这样建模

resource "create_application" "applications" {
  count             = length(local.processes)
  name              = ""
  migration_command = "" 

  dynamic "proc" {
    for_each = local.processes[count.index]

    content {
      name         = proc.value.name
      init_command = proc.value.start_cmd
      type         = proc.value.type
    }
  }
}