实现双指数平滑,又称双指数移动平均线(DEMA)

Question

如果我有时间序列数据 - {x,y}对的列表 - 并想要平滑它,我可以像这样使用指数移动平均线:

EMA[data_, alpha_:.1] := 
  Transpose @ {#1, ExponentialMovingAverage[#2, alpha]}& @@ Transpose@data

你将如何实现双指数平滑？

DEMA[data_, alpha_, gamma_] := (* unstub me! *)

如果它本身可以找出alpha和gamma的良好值,那就太好了.

---

关于如何处理时间序列中存在间隙的情况的相关问题,即样本未随时间均匀分布:

指数移动平均数在不同时间采样

Answer 1

我不确定这是可以获得的最快的代码，但以下似乎可以做到这一点：

DEMA[data_, alpha_, gamma_] := 
 Module[{st = First[data], bt = data[[2]] - data[[1]], btnew, stnew},
  Reap[
    Sow[st];
    Do[
     stnew = alpha y + (1 - alpha) (st + bt);
     btnew = gamma (stnew - st) + (1 - gamma) bt;
     Sow[stnew];
     st = stnew;
     bt = btnew;
     , {y, Rest@data}]][[-1, 1]
   ]]

这几乎是直接来自您引用的页面。您可以在源代码中修改b的初始条件。最初将 bt 设置为零可恢复单指数平滑。

In[81]:= DEMA[{a, b, c, d}, alpha, gamma]

Out[81]= {a, (1 - alpha) b + alpha b, 
 alpha c + (1 - alpha) ((1 - alpha) b + 
     alpha b + (-a + b) (1 - gamma) + (-a + (1 - alpha) b + 
        alpha b) gamma), 
 alpha d + (1 - 
     alpha) (alpha c + (1 - 
        gamma) ((-a + b) (1 - gamma) + (-a + (1 - alpha) b + 
           alpha b) gamma) + (1 - alpha) ((1 - alpha) b + 
        alpha b + (-a + b) (1 - gamma) + (-a + (1 - alpha) b + 
           alpha b) gamma) + 
     gamma (-(1 - alpha) b - alpha b + 
        alpha c + (1 - alpha) ((1 - alpha) b + 
           alpha b + (-a + b) (1 - gamma) + (-a + (1 - alpha) b + 
              alpha b) gamma)))}