Perl6中是否存在“钳位”方法/范围/数值等子

Question

Perl6中是否有“钳位”或等效方法或子方法？

例如

my $range= (1.0 .. 9.9)
my $val=15.3;

my $clamped=$range.clamp($val);
# $clamped would be 9.9

$val= -1.3;
$clamped=$range.clamp($val);
# $clamped would be 1.0

干杯

Answer 1

您可能想探究的另一个技巧是使用Proxy，它使您可以在从容器中获取或存储值时定义“挂钩”

sub limited-num(Range $range) is rw {
    my ($min, $max) = $range.minmax;
    my Numeric $store = $min;
    Proxy.new(
        FETCH => method () { $store },
        STORE => method ($new) {
            $store = max($min, min($max, $new));
        }
    )
}

# Note the use of binding operator `:=`
my $ln := limited-num(1.0 .. 9.9);
say $ln;     # OUTPUT: 1

$ln += 4.2;  
say $ln;     # OUTPUT: 5.2

$ln += 100;  
say $ln;     # OUTPUT: 9.9

$ln -= 50;   
say $ln;     # OUTPUT: 1

$ln = 0;     
say $ln;     # OUTPUT: 1

该特殊代码limited-num将使用其最小值进行初始化，但您也可以在声明时进行设置

my $ln1 := limited-num(1.0 .. 9.9) = 5.5;
say $ln1;    # OUTPUT 5.5;

my $ln2 := limited-num(1.0 .. 9.9) = 1000;
say $ln2;    # OUTPUT 9.9

Answer 2

我不这么认为。因此，也许：

multi clamp ($range, $value) {
  given $range {
    return .max when (($value cmp .max) === More);
    return .min when (($value cmp .min) === Less);
  }
  return $value
} 
my $range = (1.0 .. 9.9);
say $range.&clamp: 15.3; # 9.9
say $range.&clamp: -1.3; # 1

my $range = 'b'..'y';
say $range.&clamp: 'a'; # b
say $range.&clamp: 'z'; # y

在MOP允许您P6系统中可用的对象的直接探测。一个特别方便的元方法.^methods适用于大多数内置对象：

say Range.^methods; # (new excludes-min excludes-max infinite is-int ...

默认情况下，这仅包括在Range类中定义的方法，而不包括其继承的方法。（要获得它们，您可以使用的所有东西say Range.^methods: :all。这将使您获得更多的清单。）

当我尝试使用它时，我发现它还包含了许多无用的方法Method+{is-nodal}.new。因此，也许可以改用以下代码：

say Range.^methods.grep: * !~~ / 'is-nodal' /;

该网：

(new excludes-min excludes-max infinite is-int elems iterator
flat reverse first bounds int-bounds fmt ASSIGN-POS roll pick
Capture push append unshift prepend shift pop sum rand in-range
hyper lazy-if lazy item race of is-lazy WHICH Str ACCEPTS perl
Numeric min max BUILDALL)

这就是我用来引导我上述解决方案的原因；我有点知道这些方法，但是.^methods经常提醒我。

探索可用资源的另一种方法是doc，例如官方doc Range页面。这使我感动：

ACCEPTS min excludes-min max excludes-max bounds
infinite is-int int-bounds minmax elems list flat
pick roll sum reverse Capture rand

出于好奇，将这两个列表（排序和装箱）进行比较：

say

<ACCEPTS ASSIGN-POS BUILDALL Capture Numeric Str WHICH append
 bounds elems excludes-max excludes-min first flat fmt hyper 
 in-range infinite int-bounds is-int is-lazy item iterator
 lazy lazy-if max min new of perl pick pop prepend push
 race rand reverse roll shift sum unshift>.Bag

 ?

<ACCEPTS Capture bounds elems excludes-max excludes-min flat
 infinite int-bounds is-int list max min minmax pick
 rand reverse roll sum>.Bag

显示：

Bag(ACCEPTS, Capture, bounds, elems, excludes-max, excludes-min,
flat, infinite, int-bounds, is-int, max, min, pick,
rand, reverse, roll, sum)

因此，出于某种原因，list，minmax，和sum被记录为Range方法，但都没有被我列出的.^methods电话。大概他们被称为Method+{is-nodal}.new。嗯

say Range.^lookup('minmax'); # Method+{is-nodal}.new
say Range.^lookup('minmax').name; # minmax

是的 嗯 所以我可以写：

say Range.^methods>>.name.sort;

(ACCEPTS ASSIGN-POS AT-POS BUILDALL Bag BagHash Capture EXISTS-POS
 Mix MixHash Numeric Set SetHash Str WHICH append bounds elems
 excludes-max excludes-min first flat fmt hyper in-range infinite
 int-bounds is-int is-lazy item iterator lazy lazy-if list max min
 minmax new of perl pick pop prepend push race rand reverse roll
 shift sum unshift)

无论如何，希望对您有所帮助。