如何将 YouTube 喜欢和不喜欢以及比例从 YouTube 导入 Google 表格？

Question

xpath从视频中获取 YouTube 喜欢和不喜欢的正确方法是什么？

Answer 1

标题：

=IMPORTXML("https://www.youtube.com/watch?v=MkgR0SxmMKo","//*[@id='eow-title']")

或者：

=REGEXEXTRACT(QUERY(ARRAY_CONSTRAIN(IMPORTDATA(A12), 500, 1),
 "where Col1 contains '/title'", 0), ">(.+)<")

观点：

=VALUE(REGEXREPLACE(TEXT(IMPORTXML("https://www.youtube.com/watch?v=MkgR0SxmMKo",
 "//*[contains(@class, 'watch-view-count')]"),0)," view(s)?",""))

期间：

=SUBSTITUTE(REGEXREPLACE(IMPORTXML("https://www.youtube.com/watch?v=MkgR0SxmMKo","//*[@itemprop='duration']/@content"),"PT|S",""),"M",":")

喜欢：

=IF(ISNA(IMPORTXML("https://www.youtube.com/watch?v=MkgR0SxmMKo","(//*[contains(@class,'like-button-renderer-like-button')])[1]"))=TRUE,0,
         IMPORTXML("https://www.youtube.com/watch?v=MkgR0SxmMKo","(//*[contains(@class,'like-button-renderer-like-button')])[1]"))

不喜欢：

=IF(ISNA(IMPORTXML("https://www.youtube.com/watch?v=MkgR0SxmMKo","(//*[contains(@class,'like-button-renderer-dislike-button')])[1]"))=TRUE,0,
         IMPORTXML("https://www.youtube.com/watch?v=MkgR0SxmMKo","(//*[contains(@class,'like-button-renderer-dislike-button')])[1]"))

已上传：

=REGEXREPLACE(IMPORTXML("https://www.youtube.com/watch?v=MkgR0SxmMKo",
 "//*[contains(@class, 'watch-time-text')]"),"((Uploaded)|(Published)|(Streamed live)) on ","")

订阅：

=IFERROR(MID(QUERY(IMPORTXML("https://www.youtube.com/channel/"&A1,
 "//div[@class='primary-header-actions']"), "select Col1"), 31, 20), )

频道名称：

=INDEX(IMPORTHTML("https://www.youtube.com/channel/UC7_gcs09iThXybpVgjHZ_7g","list",1),1,1)

频道编号：

=ARRAYFORMULA(REGEXREPLACE(QUERY(SUBSTITUTE(ARRAY_CONSTRAIN(
 IMPORTDATA(https://www.youtube.com/watch?v=rckrnYw5sOA), 3000, 1), """", ""),
 "where Col1 contains '<meta itemprop=channelId content='"),
 "<meta itemprop=channelId content=|>", ""))

更新：

频道名称 (07/07/2021):

=REGEXEXTRACT(QUERY(FLATTEN(IMPORTDATA(A4)), 
 "where Col1 contains '\x22channelName\x22:\x22'", 0), ":\\x22(.+)\\x22$")

视频标题 (08/08/2021)

=REGEXEXTRACT(QUERY(FLATTEN(IMPORTDATA(A1)), 
 "where Col1 starts with 'title:""'", 0), """(.*)""")

持续时间（21/04/2022）

=TEXT(1*REGEXEXTRACT(QUERY(FLATTEN(IMPORTDATA(B1)), 
 "where Col1 contains 'approxDurationMs' limit 1", ), 
 "\d+")/3600000/24, "mm:ss")

频道观看次数 (07/06/2022)

=REGEXEXTRACT(QUERY(FLATTEN(IMPORTXML(A1, "//*")), 
 "where Col1 contains '"&CHAR(10)&"Creators'", ), 
 ".x22text.x22:.x22(.+).x22,.x22bold.x22")

视频观看次数 (01/09/2022)

=REGEXEXTRACT(QUERY(FLATTEN(IMPORTDATA(A1)); 
 "where Col1 starts with 'viewCount'"; ); "\d+")*1