是否可以表示依赖于其他参数类型的字段类型？

Question

作为一个人为的例子,假设我有一个参数结构 T <: AbstractFloat

mutable struct Summary{T<:AbstractFloat}

    count
    sum::T

end

我想输入count字段UInt16时,T === Float16或UInt32当T === Float32和UInt64其他所有情况.

我目前的做法是使用一个联合类型Union{UInt16, UInt32, UInt64}的count字段

module SummaryStats

export Summary, avg

const CounterType = Union{UInt16, UInt32, UInt64}

mutable struct Summary{T<:AbstractFloat}

    count::CounterType
    sum::T
    # explicitly typed no-arg constructor
    Summary{T}() where {T<:AbstractFloat} = new(_counter(T), zero(T))
end

# untyped no-arg constructor defaults to Float64
Summary() = Summary{Float64}()

function avg(summary::Summary{T})::T where {T <: AbstractFloat}
    if summary.count > zero(_counter(typeof(T)))
        summary.sum / summary.count
    else
        zero(T)
    end
end

# internal helper functions, not exported
Base.@pure _counter(::Type{Float16})::UInt16 = UInt16(0)
Base.@pure _counter(::Type{Float32})::UInt32 = UInt32(0)
Base.@pure _counter(::DataType)::UInt64 = UInt64(0)

end # module

这似乎有效,但显然,@code_warntype对该count领域的联合类型不满意.

我想知道是否有可能按照上面列出的规则以某种方式计算正确的混凝土类型？

Answer 1

在"外才"的构造主要是为这些有点用例:

julia> const CounterType = Union{UInt16, UInt32, UInt64}
Union{UInt16, UInt32, UInt64}

julia> mutable struct Summary{T<:AbstractFloat, S<:CounterType}
           count::S
           sum::T
           function Summary{T}() where {T<:AbstractFloat}
               S = T === Float16 ? UInt16 : 
                   T === Float32 ? UInt32 :
                   T === Float64 ? UInt64 : throw(ArgumentError("unexpected type: $(T)!"))
               new{T,S}(zero(S), zero(T))
           end
       end

julia> Summary() = Summary{Float64}()
Summary

julia> function avg(summary::Summary{T})::T where {T <: AbstractFloat}
       if summary.count > zero(summary.count)
           summary.sum / summary.count
       else
           zero(T)
       end
   end
avg (generic function with 1 method)

julia> avg(Summary())
0.0

julia> @code_warntype avg(Summary())
Body::Float64
1 ? %1 = (Base.getfield)(summary, :count)::UInt64
?   %2 = (Base.ult_int)(0x0000000000000000, %1)::Bool
???      goto #3 if not %2
2 ? %4 = (Base.getfield)(summary, :sum)::Float64
?   %5 = (Base.getfield)(summary, :count)::UInt64
?   %6 = (Base.uitofp)(Float64, %5)::Float64
?   %7 = (Base.div_float)(%4, %6)::Float64
???      return %7
3 ?      return 0.0

julia> @code_warntype avg(Summary{Float32}())
Body::Float32
1 ? %1 = (Base.getfield)(summary, :count)::UInt32
?   %2 = (Base.ult_int)(0x00000000, %1)::Bool
???      goto #3 if not %2
2 ? %4 = (Base.getfield)(summary, :sum)::Float32
?   %5 = (Base.getfield)(summary, :count)::UInt32
?   %6 = (Base.uitofp)(Float32, %5)::Float32
?   %7 = (Base.div_float)(%4, %6)::Float32
???      return %7
3 ?      return 0.0f0