如何在WebGL中实现像隧道动画这样的隧道？

Question

如何在WebGL中实现像隧道动画这样的隧道？

资料来源:http://dvdp.tumblr.com/

另请参见:如何在WebGL中实现此旋转螺旋？

Answer 1

嗯,这很有趣.:)

这里有一个WebGL演示:http://boblycat.org/~knute/webgl/tunnel/

(编辑:不再可用,但我创建了ShaderToy版本:https://www.shadertoy.com/view/XdKfRD )

主要算法在片段着色器中.基本思想是for循环迭代黑色环/圆,从大到小,也偏移中心以产生类似隧道的效果.

给定任何像素,我们可以检查像素是否足够接近环以成为黑色像素的候选者.如果它在环外,打破环路以避免通过较大的环看到较小的环.

当环闭合时,与前一个(外部)圆的距离用于将图案"挤压"在一起,这有助于产生3D表面的错觉.

每个环的波浪形图案当然是正弦曲线.像素的角度(与圆心相比)与均匀的时间参数组合以为每个环的波浪图案设置动画.

最后,有很多实验使用不同的参数和转换函数,如pow(),以使结果接近目标动画.它并不完美,但非常接近.

片段着色器代码:

#ifdef GL_ES
precision highp float;
#endif

const float PI = 3.14159265358979323846264;
const float TWOPI = PI*2.0;

const vec4 WHITE = vec4(1.0, 1.0, 1.0, 1.0);
const vec4 BLACK = vec4(0.0, 0.0, 0.0, 1.0);

const vec2 CENTER = vec2(0.0, 0.0);

const int MAX_RINGS = 30;
const float RING_DISTANCE = 0.05;
const float WAVE_COUNT = 60.0;
const float WAVE_DEPTH = 0.04;

uniform float uTime;
varying vec2 vPosition;

void main(void) {
    float rot = mod(uTime*0.0006, TWOPI);
    float x = vPosition.x;
    float y = vPosition.y;

    bool black = false;
    float prevRingDist = RING_DISTANCE;
    for (int i = 0; i < MAX_RINGS; i++) {
        vec2 center = vec2(0.0, 0.7 - RING_DISTANCE * float(i)*1.2);
        float radius = 0.5 + RING_DISTANCE / (pow(float(i+5), 1.1)*0.006);
        float dist = distance(center, vPosition);
        dist = pow(dist, 0.3);
        float ringDist = abs(dist-radius);
        if (ringDist < RING_DISTANCE*prevRingDist*7.0) {
            float angle = atan(y - center.y, x - center.x);
            float thickness = 1.1 * abs(dist - radius) / prevRingDist;
            float depthFactor = WAVE_DEPTH * sin((angle+rot*radius) * WAVE_COUNT);
            if (dist > radius) {
                black = (thickness < RING_DISTANCE * 5.0 - depthFactor * 2.0);
            }
            else {
                black = (thickness < RING_DISTANCE * 5.0 + depthFactor);
            }
            break;
        }
        if (dist > radius) break;
        prevRingDist = ringDist;
    }

    gl_FragColor = black ? BLACK : WHITE;
}