简化常用方法的调用

Question

我有一个这样的课:

class Foo {
    method some-method(Str $name) { ... }
}

用法简单:

my $foo = Foo.new;

$foo.some-method("peter");

由于"some-method"将被频繁调用,我想做一些事情以允许用户使用它,如下所示:

$foo.peter;

我知道FALLBACK会完成这项工作,但它已被用于另一种方法.我试图定义一个中缀运算符:

sub infix:<%>(Foo $foo, $name) {
    $foo.some-method($name);
}

下面的代码有效,但双引号很烦人.

$foo % "peter";

那么有什么方法可以避免引号？或者以何种方式简化调用？

Answer 1

正如Curt Tilmes已经指出的那样,你可以让你的Foo对象充当Associative(或Hash):

class Foo {
    method some-method(Str $name) { ... }
    method AT-KEY(Str $name) { self.some-method($name) }
}
my $foo = Foo.new;
say $foo<peter>;   # same as $foo.some-method("peter")

当然,这个AT-KEY方法可以是多方法,所以你也可以用它来玩各种各样的技巧.

class Foo {
    method some-method(Str $name) { "$name is ok" }
    multi method AT-KEY("peter")   { "peter is special" }
    multi method AT-KEY(Str $name) { self.some-method($name) }
}
my $foo = Foo.new;
say $foo<peter>;   # "peter is special"
say $foo<joe>;     # "joe is ok"

Answer 2

有一种方法可以FALLBACK用于多个操作,只要它们在某种程度上不同.

• 通过检查对象的某些属性:

  class Foo {
    # this could be set as part of `new`/`BUILD`
    has %!special = ( "peter" => 42 );
  
    multi method FALLBACK ( $name where (%!special{$name}:exists) ) {
      %!special{$name}
    }
  
    multi method FALLBACK ( $other ) {
      $other.tc
    }
  }
  
  with Foo.new {
    say .paul; # Paul
    say .peter; # 42
  }
  

  这具有远距离动作的潜在问题.

• 使用不同数量或类型的参数:

  class Bar {
    multi method FALLBACK ( Str:D $name ) {
      $name.tc
    }
    multi method FALLBACK ( Str:D $name, Real:D $number ) {
      $name.tc, 1 / $number
    }
    multi method FALLBACK ( Str:D $name, Str:D $other ) {
      $name.tc, $other.uc
    }
  }
  
  with Bar.new {
    say .paul;          # Paul
    say .peter(42);     # Peter, 0.02381
    say .peter('Paul'); # Peter, PAUL
  }
  

您可以使用.[…]Int参数.

class Baz {
  method AT-POS ( $arg ) { say "Baz[$arg]" }
}
Baz.new[42,32]; # Baz[42]
                # Baz[32]

内置postcircumfix:« [ ] »强制Int的参数,但你可以添加一个新的混合.
(这有很多警告.)

multi sub postcircumfix:<[ ]> ( Baz:D $b, $a ) is export {
  # $b.AT-POS( $a )

  $b.some-method( $a )
}

您可以使用.<…>空格分隔的Strs或.{…}任意值.

class Other {
  multi method AT-KEY ( Str:D $name ){
    $name.tc
  }
  multi method AT-KEY ( Real:D $number ){
    1 / $number
  }
}

with Other.new {
  say $_<peter>;     # Peter
  say $_.<paul>;     # Paul
  say .<peter paul>; # Peter Paul
  # note that AT-Key got called twice

  say $_{42,'peter'}; # 0.02381, Peter
  # note that AT-Key got called twice
}

您可以使它对象可以调用.

class Fubar {
  multi method CALL-ME ( Str:D $name ){
    $name.tc
  }
  multi method CALL-ME ( Real:D $number ){
    1 / $number
  }
  multi method CALL-ME ( +@args ){
    @args.map: {self.CALL-ME($_)}
  }
}

with Fubar.new {
  say $_('peter');   # Peter
  say $_(42);        # 0.02381

  # this calls the +@args one
  say $_('paul',32); # Paul, 0.03125
}

在进行任何这些操作之前,您应该考虑一下您的API.