ANTLR 语法行 1:6 不匹配输入 '<EOF>' 期待 '.'

Question

我在玩 antlr4 语法文件，我想编写自己的jsonpath语法。

我想出了这个：

grammar ObjectPath;

objectPath      : dnot;

dnot            : ROOT expr ('.' expr)
                | EOF
                ;

expr            : select #selectExpr
                | ID #idExpr
                ;

select          : ID '[]' #selectAll
                | ID '[' INT ']' #selectIndex
                | ID '[' INT (',' INT)* ']' #selectIndexes
                | ID '[' INT ':' INT ']' #selectRange
                | ID '[' INT ':]' #selectFrom
                | ID '[:' INT ']' #selectUntil
                | ID '[-' INT ':]' #selectLast
                | ID '[?(' query ')]' #selectQuery
                ;

query           : expr (AND|OR) expr # andOr
                | ALL # all
                | QPREF ID # prop
                | QPREF ID GT INT # gt
                | QPREF ID LT INT # lt
                | QPREF ID EQ INT # eq
                | QPREF ID GTE INT # gte
                | QPREF ID LTE INT # lte
                ;

/** Lexer **/
ROOT    : '$.' ;
QPREF   : '@.' ;
ID      : [a-zA-Z][a-zA-Z0-9]* ;
INT     : '0' | [1-9][0-9]* ;
AND     : '&&' ;
OR      : '||' ;
GT      : '>'  ;
LT      : '<'  ;
EQ      : '==' ;
GTE     : '>=' ;
LTE     : '<=' ;
ALL     : '*'  ;

在一个简单的表达式上运行后：

CharStream input = CharStreams.fromString("$.name");
ObjectPathLexer lexer = new ObjectPathLexer(input);
CommonTokenStream tokens = new CommonTokenStream(lexer);

ObjectPathParser parser = new ObjectPathParser(tokens);
ParseTree parseTree = parser.dnot();
ObjectPathDefaultVisitor visitor = ...
System.out.println(visitor.visit(parseTree));
System.out.println(parseTree.toStringTree(parser));

输出没问题，这意味着“名称”实际上是从 json 中检索到的，但是有一个我无法解释的警告：

line 1:6 mismatched input '<EOF>' expecting '.'

我读过我需要明确地将 EOF 规则添加到我的起始规则 ( dnot) 中，但这似乎不起作用。

知道我能做什么吗？

Answer 1

您$.name的规则无法解析您的输入：

dnot            : ROOT expr ('.' expr)
                | EOF
                ;

$.name 产生 2 个令牌：

1. ROOT
2. ID

但是您的第一个选择 ,ROOT expr ('.' expr)需要 2 个由 a 分隔的表达式.。也许您打算将第二个 expr 设为可选，如下所示：

dnot            : ROOT expr ('.' expr)*
                | EOF
                ;

并且EOF通常添加在开始规则的末尾，以强制解析器消耗所有令牌。正如您现在所做的那样，解析器成功解析了ROOT expr，但无法进一步解析，并产生您看到的警告（期待“.”）。

由于objectPath似乎是您的开始规则，我认为这就是您想要做的：

objectPath      : dnot EOF;

dnot            : ROOT expr ('.' expr)?
                ;

此外，代币这样的[]，'[?('等看起来很可疑。我对对象路径不是很熟悉，但是通过将这些字符相互粘合，这样的输入[ ]（[并]用空格分隔）将不会被[]. 所以如果foo[ ]有效，我会这样写：

select          : ID '[' ']' #selectAll
                | ...

并跳过词法分析器中的空格：

SPACES : [ \t\r\n]+ -> skip;