无法配置 CMake 以查找安装了 Homebrew 的 Bison 版本

Question

我正在运行 macOS 10.14 并且我安装了bison3.2 版brew，但它拒绝链接：

$ brew link bison --force
Warning: Refusing to link macOS-provided software: bison
If you need to have bison first in your PATH run:
  echo 'export PATH="/usr/local/opt/bison/bin:$PATH"' >> ~/.bash_profile

For compilers to find bison you may need to set:
  export LDFLAGS="-L/usr/local/opt/bison/lib"

我CMakeLists.txt有以下几行：

find_package(BISON 3.2 REQUIRED)
...
message(STATUS "Found bison ${BISON_VERSION} at: ${BISON_EXECUTABLE}")

cmake 失败并显示以下输出：

Could NOT find BISON: Found unsuitable version "2.3", but required is at
least "3.2" (found /usr/bin/bison)

系统安装的bison是 2.3 版，我知道 Homebrew 安装的版本是 3.2 版。

该FindBISON模块显然使用了find_programCMake 指令，我尝试添加/usr/local/opt/bison/bin到CMAKE_PROGRAM_PATH，但/usr/bin/bison无论如何总是首先选择。如何强制 CMake 支持 Bison 可执行文件的 Homebrew 安装版本？

Answer 1

由于 macos 中的某些东西依赖于 Apple 提供的 flex 和 bison 版本，自制软件将它们安装在用户正常范围之外$PATH作为“小桶”。手动解决方案是确保您（和您的用户）将程序的 brew 前缀添加到他们的路径中（可以通过运行brew --prefix bison等找到）。

一个自动的解决方案是将此逻辑放在您的 CMake 文件中。一些开源项目已经像这样解决了这个问题。我能找到的最早修复示例来自对 STP 的提交（下面复制了基本部分）。

在处理所有这些时，请务必清除您的 CMake 缓存，因为BISON_EXECUTABLE（等）已被缓存。

# On macOS, search Homebrew for keg-only versions of Bison and Flex. Xcode does
# not provide new enough versions for us to use.
if (CMAKE_HOST_SYSTEM_NAME MATCHES "Darwin")
    execute_process(
        COMMAND brew --prefix bison
        RESULT_VARIABLE BREW_BISON
        OUTPUT_VARIABLE BREW_BISON_PREFIX
        OUTPUT_STRIP_TRAILING_WHITESPACE
    )
    if (BREW_BISON EQUAL 0 AND EXISTS "${BREW_BISON_PREFIX}")
        message(STATUS "Found Bison keg installed by Homebrew at ${BREW_BISON_PREFIX}")
        set(BISON_EXECUTABLE "${BREW_BISON_PREFIX}/bin/bison")
    endif()

    execute_process(
        COMMAND brew --prefix flex
        RESULT_VARIABLE BREW_FLEX
        OUTPUT_VARIABLE BREW_FLEX_PREFIX
        OUTPUT_STRIP_TRAILING_WHITESPACE
    )
    if (BREW_FLEX EQUAL 0 AND EXISTS "${BREW_FLEX_PREFIX}")
        message(STATUS "Found Flex keg installed by Homebrew at ${BREW_FLEX_PREFIX}")
        set(FLEX_EXECUTABLE "${BREW_FLEX_PREFIX}/bin/flex")
    endif()
endif()

find_package(bison REQUIRED)
find_package(flex REQUIRED)