Delphi - 将线程与帧同步

Question

下午好:-),我有一个框架.此框架由Main Form动态创建.

主要形式:

Interface := TInterface.Create(self);
    with handlingInterface do begin
      Parent := Form1;
      Left := 0; Top := 35;
      Width := 570; Height := 250;
    end;

在Frame中我有一个Thread.我从Frame调用这个Thread.为什么我可以将Thread与Frame同步？没有:

var
Form1: TForm1;

---

我在Frame中调用Thread,我想在Frame中更改ProgressBar的位置.我不知道,为什么我可以在Thread的Synchronize方法中访问ProgressBar.

如果是Form中的Thread和ProgressBar - Synchronize访问是Form1.ProgressBar ...

但我在Frame中有Thread和ProgressBar .

Answer 1

如果你要做的唯一事情是从线程更新进度条,那么有一个更轻的权重选项.我会考虑使用PostMessage.你不希望你的线程过多地了解框架的细节.

创建线程时,请为其提供框架的句柄,以便知道在何处发布消息.让框架侦听Windows消息,其中包括进度位置,并更新进度条.

这是一个非常简单的示例,它将进度条从0增加到100,每个增量之间的睡眠时间很短:

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls;

const
  WM_PROGRESS_MESSAGE = WM_USER + 99;

type
  TProgressThread = class(TThread)
  private
    FWindowHandle: HWND;
  protected
    procedure Execute; override;
  public
    property WindowHandle: HWND read FWindowHandle write FWindowHandle;
  end;

  TFrame2 = class(TFrame)
    ProgressBar1: TProgressBar;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    procedure OnProgressMessage(var Msg: TMessage); message WM_PROGRESS_MESSAGE;
  public
  end;

implementation

{$R *.dfm}

{ TFrame2 }

procedure TFrame2.Button1Click(Sender: TObject);
var
  lThread: TProgressThread;
begin
  lThread := TProgressThread.Create(True);
  lThread.FreeOnTerminate := True;
  lThread.WindowHandle := Self.Handle;
  lThread.Start;
end;

procedure TFrame2.OnProgressMessage(var Msg: TMessage);
begin
  ProgressBar1.Position := Msg.WParam;
end;


{ TProgressThread }

procedure TProgressThread.Execute;
var
  lProgressCount: Integer;
begin
  inherited;

  for lProgressCount := 0 to 100 do
  begin
    PostMessage(FWindowHandle, WM_PROGRESS_MESSAGE, lProgressCount, 0);
    Sleep(15);
  end;
end;

end.