Swift编译器/链接器是否会自动删除未使用的方法/类/扩展名等？

Question

我们有很多代码可在我们编写的任何iOS应用程序中使用。诸如：

• 自定义/通用控件
• 对常见对象的扩展，例如UIView，UIImage和UIViewController
• 全局实用程序功能
• 全局常数
• 构成常见“功能”的相关文件集，例如可以与可枚举的任何内容一起使用的选择器屏幕。

由于与该问题无关的原因，我们不能使用静态或动态库。这些必须作为实际源文件包含在项目中。

这些“核心”文件有几百个，因此我一直在做的工作是将所有文件添加到项目中（引用磁盘上的共享位置），但是仅在使用/需要它们时才将它们添加到特定目标中。

问题是这样做变得非常繁琐，尤其是当存在所有都引用其他文件的相关文件集时。追踪他们一个人真是痛苦！

我想知道的是，是否可以仅将所有内容都包含在目标中，然后依靠编译器删除所有未使用的代码。

例如，我在UIView上有几种扩展方法。如果我没有在特定的目标中使用它们，编译器会将该代码从已编译的二进制文件中排除，还是将其编译到无法访问的位置而无故膨胀代码大小？

Answer 1

无效功能

编译器的SILOptimizer 具有失效函数消除过程，该过程消除了已知不被调用的函数和方法（以及任何关联的vtable /见证表条目）。

为了充分利用这一点，您将需要使用整个模块优化（-wmo），以确保编译器可以分析是否internal在同一模块内调用了函数。

您可以轻松地自己进行测试，例如使用以下代码：

class C {}
extension C {
  @inline(never) func foo() {}
  @inline(never) func bar() {}
}

@inline(never) func foo() {}
@inline(never) func bar() {}
bar()

let c = C()
c.bar()

^{（我在@inline(never)这里使用非官方的方法来确保未通过内联优化功能）}

如果运行xcrun swiftc -emit-sil -O -wmo main.swift | xcrun swift-demangle，我们可以看到生成的SIL：

sil_stage canonical

import Builtin
import Swift
import SwiftShims

class C {
  init()
  deinit
}

extension C {
  @inline(never) func foo()
  @inline(never) func bar()
}

@inline(never) func foo()

@inline(never) func bar()

let c: C

// c
sil_global hidden [let] @main.c : main.C : $C

// main
sil @main : $@convention(c) (Int32, UnsafeMutablePointer<Optional<UnsafeMutablePointer<Int8>>>) -> Int32 {
bb0(%0 : $Int32, %1 : $UnsafeMutablePointer<Optional<UnsafeMutablePointer<Int8>>>):
  // function_ref bar()
  %2 = function_ref @main.bar() -> () : $@convention(thin) () -> () // user: %3
  %3 = apply %2() : $@convention(thin) () -> ()
  alloc_global @main.c : main.C                  // id: %4
  %5 = global_addr @main.c : main.C : $*C        // user: %8
  %6 = alloc_ref $C                               // users: %8, %7
  debug_value %6 : $C, let, name "self", argno 1  // id: %7
  store %6 to %5 : $*C                            // id: %8
  // function_ref specialized C.bar()
  %9 = function_ref @function signature specialization <Arg[0] = Dead> of main.C.bar() -> () : $@convention(thin) () -> () // user: %10
  %10 = apply %9() : $@convention(thin) () -> ()
  %11 = integer_literal $Builtin.Int32, 0         // user: %12
  %12 = struct $Int32 (%11 : $Builtin.Int32)      // user: %13
  return %12 : $Int32                             // id: %13
} // end sil function 'main'

// C.__deallocating_deinit
sil hidden @main.C.__deallocating_deinit : $@convention(method) (@owned C) -> () {
// %0                                             // users: %3, %2, %1
bb0(%0 : $C):
  debug_value %0 : $C, let, name "self", argno 1  // id: %1
  debug_value %0 : $C, let, name "self", argno 1  // id: %2
  dealloc_ref %0 : $C                             // id: %3
  %4 = tuple ()                                   // user: %5
  return %4 : $()                                 // id: %5
} // end sil function 'main.C.__deallocating_deinit'

// bar()
sil hidden [noinline] @main.bar() -> () : $@convention(thin) () -> () {
bb0:
  %0 = tuple ()                                   // user: %1
  return %0 : $()                                 // id: %1
} // end sil function 'main.bar() -> ()'

// specialized C.bar()
sil shared [noinline] @function signature specialization <Arg[0] = Dead> of main.C.bar() -> () : $@convention(thin) () -> () {
bb0:
  %0 = tuple ()                                   // user: %1
  return %0 : $()                                 // id: %1
} // end sil function 'function signature specialization <Arg[0] = Dead> of main.C.bar() -> ()'

sil_vtable C {
  #C.deinit!deallocator: @main.C.__deallocating_deinit  // C.__deallocating_deinit
}

您会注意到，只有bar函数和方法的主体发出了（靠近底部）。尽管foo在SIL的顶部仍然有一些定义，但是随着SIL降低到LLVM IR，它们将被删除。

我想知道您是否可以标记/注明“不要删除此内容！”的方法 像其他语言一样

当前没有为此的正式属性，但是有一个强调的@_optimize(none)属性，告诉优化者不要触摸：

@_optimize(none) func foo() {}

尽管强调了该属性，但使用后果自负。

无效类型元数据

不幸的是，目前的编译器（如4.2夫特的）不出现有一个优化过程，消除了已知不被使用的类型相关联的元数据。