将Protobuf与Gradle（IntelliJ）结合使用

Question

我正在尝试使用此处给出的构建指令为一个简单的protobuf 示例生成代码。我已经尝试了一段时间，但在源根目录中看不到任何自动生成的代码。

以下是我的build.gradle档案

buildscript {
    ext {
        springBootVersion = '2.0.4.RELEASE'
    }
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
        classpath "io.spring.gradle:dependency-management-plugin:1.0.3.RELEASE"
        classpath 'com.google.protobuf:protobuf-gradle-plugin:0.8.5'
    }
}

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'org.springframework.boot'
apply plugin: 'io.spring.dependency-management'
apply plugin: 'com.google.protobuf'

group = 'io.ai.vivid'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencyManagement {
    imports {
        mavenBom 'com.amazonaws:aws-java-sdk-bom:1.11.228'
    }
}

protobuf {
    protoc {
        artifact = "com.google.protobuf:protoc:3.5.1-1"
    }

    generateProtoTasks.generatedFilesBaseDir = 'generated-sources'

    plugins {
        grpc {
            artifact = 'io.grpc:protoc-gen-grpc-java:1.14.0'
        }
    }
    generateProtoTasks {
        all()*.plugins {
            grpc {}
        }
    }
}

dependencies {
    compile 'io.grpc:grpc-netty-shaded:1.14.0'
    compile 'io.grpc:grpc-protobuf:1.14.0'
    compile 'io.grpc:grpc-stub:1.14.0'
}

同样在我的build.gradle文件中，IntelliJ抱怨它无法解析名称protobuf

我尝试过的事情

• IntelliJ中的同步gradle工具。这是
  SO中最突出的解决方案

• 设置构建工具-> Gradle-> Runner-> Delelgate IDE在gradle上的构建/运行操作为true

• 彻底重建gradle项目。

根据我对GitHub帖子的理解，当您使用protobuf插件时，将自动为您生成存根。我想念什么？

Answer 1

你已经应用了idea插件，但你没有配置它。您需要告诉 idea 插件在哪里包含生成的源代码。

protobuf {
    generatedFilesBaseDir = "$projectDir/src/generated"
}
idea {
    module {
        sourceDirs += file("${projectDir}/src/generated/main/java");
        sourceDirs += file("${projectDir}/src/generated/main/grpc");
    }
}

您可以在此处查看构建文件的完整示例：build.gradle