什么是 cfi_adjust_cfa_offset 和 cfi_rel_offset？

Question

我目前正在尝试了解 glibcsyscall函数的内部代码。下面是代码（取自这里）。

/* In the EABI syscall interface, we don't need a special syscall to
   implement syscall().  It won't work reliably with 64-bit arguments
   (but that is true on many modern platforms).  */
ENTRY (syscall)
        mov        ip, sp
        push        {r4, r5, r6, r7}
        cfi_adjust_cfa_offset (16)
        cfi_rel_offset (r4, 0)
        cfi_rel_offset (r5, 4)
        cfi_rel_offset (r6, 8)
        cfi_rel_offset (r7, 12)
        mov        r7, r0
        mov        r0, r1
        mov        r1, r2
        mov        r2, r3
        ldmfd        ip, {r3, r4, r5, r6}
        swi        0x0
        pop        {r4, r5, r6, r7}
        cfi_adjust_cfa_offset (-16)
        cfi_restore (r4)
        cfi_restore (r5)
        cfi_restore (r6)
        cfi_restore (r7)
        cmn        r0, #4096
        it        cc
        RETINSTR(cc, lr)
        b        PLTJMP(syscall_error)
PSEUDO_END (syscall)

我对传递系统调用号和参数的代码有一些了解，它们是函数的核心syscall功能。但我不明白cfi_adjust_cfa_offset指令、cfi_rel_offset指令和cfi_restore指令的作用。我知道这些指令与函数的syscall功能关系不大。但是，我仍然想知道这些指令的作用。

谢谢你。

Answer 1

这些不是指令而是汇编指令（通常它们应该以 a 开头，.但在这里它们是 macros，可能是为了处理汇编器中的差异）。它们告诉汇编器对特殊元数据进行编码，这有助于调试器和异常处理程序正确展开堆栈。通常它们是由编译器发出的，所以你看不到它们，但它们在低级代码或像这里这样的手写程序集中尤其重要。

让我们来看看代码。首先，一些背景。

CFA 代表“规范帧地址”，默认情况下等于sp调用站点处的值（请参阅此处）。在 ARM 上调用不会将返回地址压入堆栈，因此sp在函数入口处是相同的。

mov ip, sp

这会将sp值（即 CFA，因此指向不适合 r0-r3 寄存器的任何其他参数）复制到ip（又名r12）寄存器。

push {r4,r5,r6, r7}

这将保存将很快修改但假定不会被调用修改的寄存器（非易失性寄存器）。push把sp值改了4*4=16个字节，就不再等于CFA了。

cfi_adjust_cfa_offset(16)

这会发出一个操作码，告诉调试器 CFA 与假定的 CFA ( sp) 的偏移量为 16 。

cfi_rel_offset(r4, 0)

这告诉调试器r4可以在新调整的 CFA 的偏移量 0 处找到的原始值。以下指令描述了其他三个保存的寄存器。

    mov        r7, r0
    mov        r0, r1
    mov        r1, r2
    mov        r2, r3
    ldmfd        ip, {r3, r4, r5, r6}
    swi        0x0

这以 EABI 调用约定期望的方式设置系统调用参数（系统调用编号 in r7，第一个参数 in r0-r6），然后调用系统调用指令

    pop        {r4, r5, r6, r7}
    cfi_adjust_cfa_offset (-16)
    cfi_restore (r4)
    cfi_restore (r5)
    cfi_restore (r6)
    cfi_restore (r7)

这里我们恢复之前保存的寄存器，将CFA调整回-16（因为sp被pop指令改变了，并指定寄存器已经恢复到原来的值）。