在Haskell中模拟路径相关类型

Question

这是我想要做的简化示例.假设您有一HList对:

let hlist = HCons (1, "1") (HCons ("0", 2) (HCons ("0", 1.5) HNil))

现在我想编写一个函数replaceAll,它将用相同类型的第一个"值"替换给定类型的所有"键".例如,有了HList上面的内容,我想替换所有的String键,"1"它是第一个String找到的类型的值HList

 replaceAll @String hlist =
    HCons (1, "1") (HCons ("1", 2) (HCons ("1", 1.5) HNil))

这似乎需要路径依赖类型,以便"提取"第一对的类型,并能够在第二步中使用它来指导键的替换,但我不知道如何在Haskell中对此进行编码.

Answer 1

这是一个证明搜索问题("查找String此列表中的事件"),因此您可以预期该解决方案将涉及类型类Prolog.我将回答你问题的一个更简单的版本(即"找到第一次出现的String")并让你弄清楚如何根据你的确切用例进行调整.

由于我们正在进行证明搜索,让我们首先写下我们将要搜索的证明对象.

data Contains a as where
    Here :: Contains a (a ': as)
    There :: Contains a as -> Contains a (b ': as)

类型值Contains a as是可以a在类型级别列表中找到的构造性证明as.在结构上,Contains就像是一个自然数(比较There (There Here)用S (S Z))识别的位置a列表中的as.要证明你a在as给它的索引.

例如,您可以replace使用HList相同类型的新元素在给定位置的元素.

replace :: a -> Contains a as -> HList as -> HList as
replace x Here (HCons y ys) = HCons x ys
replace x (There i) (HCons y ys) = HCons y (replace x i ys)

我们想要a使用类型类Prolog在给定列表中搜索.有两种情况 - 要么你找到a了列表的头部,要么它位于尾部的某个地方.(如果a不在as,则使用contains将失败并出现"无实例"错误.)理想情况下,我们会编写如下内容:

class CONTAINS a as where
    contains :: Contains a as

instance CONTAINS a (a ': as) where
    contains = Here

instance CONTAINS a as => CONTAINS a (b ': as) where
    contains = There contains  -- recursively call `contains` on the sublist

但这不符合重叠的实例规则.在实例搜索期间不检查实例上下文和类型等式 - elaborator不会回溯 - 因此这些实例都不比另一个更具体.

幸运的是,这个问题有一个众所周知的解决方案.它涉及使用封闭式家庭来分辨a和b分开.您可以CONTAINS'使用额外参数定义辅助类,在这种情况下,可以Bool告诉您是否a可以在头部找到as.

class CONTAINS' (eq :: Bool) a (as :: [*]) where
    contains' :: Contains a as

然后,当你定义实例的情况下eq是True或False.该elaborator可以分辨这种情况下,因为True和False有明显不同.请注意,步骤案例递归调用CONTAINS.

instance CONTAINS' True a (a ': as) where
    contains' = Here

instance CONTAINS a as => CONTAINS' False a (b ': as) where
    contains' = There contains

最后CONTAINS,根据一个封闭类型族来定义你的实例CONTAINS',并使用==一个封闭类型族来测试它的参数是否相等,以选择一个实例.

instance CONTAINS' (a == b) a (b ': as) => CONTAINS a (b ': as) where
    contains = contains' @(a == b)

(这是布尔类型系列中极少数可接受的用途之一.)

现在你可以CONTAINS像使用任何其他类一样使用它.当您尝试实例化a并且asGHC将尝试搜索a内部时as,该contains方法将返回其索引.

example :: Contains Int '[Bool, Int, Char]
example = contains

-- "no instance for CONTAINS"
failingExample :: Contains String '[Bool, Int, Char]
failingExample = contains

这是一个相当简单的例子,代码已经非常混乱了.你肯定可以用同样的方式在你的问题中处理这个例子,但是所有人都告诉我,我不相信静态检查在这个例子中值得复杂.您是否考虑过基于的实现Typeable？