从XML文档,XSLT和JAXB中删除元素

Question

这个问题是我之前提出的问题的后续问题: 创建一个使用<all>和<any>元素打开的有效XSD

鉴于我有一个包含以下形式的XML文档的Java String:

<TRADE>
  <TIME>12:12</TIME>
  <MJELLO>12345</MJELLO>
  <OPTIONAL>12:12</OPTIONAL>
  <DATE>25-10-2011</DATE>
  <HELLO>hello should be ignored</HELLO>
</TRADE>

我如何使用XSLT或类似的东西(在Java中使用JAXB)来删除一组元素中未包含的所有元素.在上面的例子中,我只对(TIME,OPTIONAL,DATE)感兴趣,所以我想将其转换为:

<TRADE>
  <TIME>12:12</TIME>
  <OPTIONAL>12:12</OPTIONAL>
  <DATE>25-10-2011</DATE>
</TRADE>

元素的顺序不固定.

Answer 1

这种转变:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pNames" select="'|TIME|OPTIONAL|DATE|'"/>
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="*/*">
  <xsl:if test="contains($pNames, concat('|', name(), '|'))">
   <xsl:call-template name="identity"/>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当应用于提供的XML文档时:

<TRADE>
    <TIME>12:12</TIME>
    <MJELLO>12345</MJELLO>
    <OPTIONAL>12:12</OPTIONAL>
    <DATE>25-10-2011</DATE>
    <HELLO>hello should be ignored</HELLO>
</TRADE>

产生想要的,正确的结果:

<TRADE>
   <TIME>12:12</TIME>
   <OPTIONAL>12:12</OPTIONAL>
   <DATE>25-10-2011</DATE>
</TRADE>

说明:

1. 身份规则(模板) "按原样" 复制每个节点.

2. 标识匹配任何不是文档顶部元素的元素的模板会覆盖标识规则.在模板内部,检查匹配元素的名称是否是$pNames在管道分隔的有名名称字符串中的外部参数中指定的名称之一.

3. 请参阅XSLT处理器的文档,了解如何将参数传递给转换 - 这取决于实现,因处理器而异.