如何在Forth中输入数字

Question

是否有类似于inputBasic或scanf("%d")C in Forth的东西？

可能会是这样的:

200 buffer: buf
: input ( -- n ) buf 200 accept 
  some-magic-filter
  buf swap evaluate ;

上面代码中的问题是如何定义一个只传递数字的过滤器,而不是任何单词,定义等？

Answer 1

该标准仅指定>NUMBER用于解释整数的低级字.EVALUATE用于将字符串转换为数字的OTOH 是一种快速而肮脏的方式.要么在没有检查的情况下使用它(在可信输入的情况下),要么根本不使用它.之前尝试过滤字符串EVALUATE是一个坏主意:它>NUMBER本身就是单词成本和重用率低.

注意:既不检测>NUMBER也不EVALUATE检测数字溢出.

在任何情况下,输入单个单元整数的单词都可以定义为:

: accept-number ( -- n )
  PAD DUP 80 ACCEPT ( addr u ) StoN ( n )
;

在可信输入的情况下,您可以定义StoN类似

: StoN ( addr u -- x )
  STATE @ ABORT" This naive StoN should not be used in compilation state"
  DEPTH 2- >R
    EVALUATE
  DEPTH 1- R> <> IF -24 THROW THEN
  \ check depth to accept the single-cell numbers only
;

否则(在不可信输入的情况下)您有两种选择:依赖特定Forth系统的特定单词或使用某些(可能是您自己的)库.

我使用以下词典来定义StoN:

\ ---
\ The words from Substring Matching library
\ (where length is counted in address units)

: MATCH-HEAD ( a u a-key u-key -- a-right u-right true | a u false ) 
  2 PICK OVER U< IF  2DROP FALSE EXIT THEN 
  DUP >R
  3 PICK R@ COMPARE IF  RDROP FALSE EXIT THEN 
  SWAP R@ + SWAP R> - TRUE
; 

\ ---
\ The words from Literals interpreting library
\ (where prefix 'I-' is shortcut for Interpret)

: I-DLIT ( a u -- x x true | a u false ) 
  2DUP S" -"  MATCH-HEAD >R
  DUP 0= IF  NIP RDROP EXIT THEN 
  0 0 2SWAP >NUMBER NIP IF  RDROP 2DROP FALSE EXIT THEN 
  R> IF  DNEGATE THEN  2SWAP 2DROP TRUE
; 

: I-LIT ( a u -- x true | a u false ) 
  I-DLIT IF  D>S TRUE EXIT THEN  FALSE
;

之后StoN可以定义为:

: StoN ( a u -- x ) I-LIT IF EXIT THEN -24 THROW ;

上面提到的库可以在GitHub找到:

• 子串匹配函数库
• 解析器示例(针对各种词位)