如何在主模式挂钩中访问目录本地变量？

Question

我已经定义了一个.dir-locals.el文件,其中包含以下内容:

((python-mode . ((cr/virtualenv-name . "saas"))))

在我的.emacs中,我有以下函数来检索此值并提供virtualenv路径:

(defun cr/virtualenv ()
  (cond (cr/virtualenv-name (format "%s/%s" virtualenv-base cr/virtualenv-name))
        ((getenv "EMACS_VIRTUAL_ENV") (getenv "EMACS_VIRTUAL_ENV"))
        (t "~/.emacs.d/python")))

最后,在我的python-mode-hook列表中,我有这个钩子函数:

(add-hook 'python-mode-hook 'cr/python-mode-shell-setup)

(defun cr/python-mode-shell-setup ()
  (message "virtualenv-name is %s" cr/virtualenv-name)
  (let ((python-base (cr/virtualenv)))
    (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
           (setq python-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command-args '( "-colors" "NoColor")))
          (t
           (setq python-python-command (concat python-base "/bin/python"))
           (setq py-python-command (concat python-base "/bin/python"))
           (setq py-python-command-args nil)))))

当我打开一个新的python文件时,记录的消息cr/python-mode-shell-setup表明它cr/virtualenv-name是nil.但是,当我知道这个名字时,我会得到"saas".

显然这里有一个加载订单问题; 有没有办法让我的模式钩子语句响应目录本地变量？

Answer 1

这是因为normal-mode调用(set-auto-mode)和(hack-local-variables)按此顺序发生的.

但是hack-local-variables-hook,在处理局部变量之后运行,这将启用一些解决方案:

1. 第一个是让Emacs为每个主要模式运行一个新的"局部变量挂钩":

   (add-hook 'hack-local-variables-hook 'run-local-vars-mode-hook)
   (defun run-local-vars-mode-hook ()
     "Run a hook for the major-mode after the local variables have been processed."
     (run-hooks (intern (concat (symbol-name major-mode) "-local-vars-hook"))))
   
   (add-hook 'python-mode-local-vars-hook 'cr/python-mode-shell-setup)
   

   (您的原始功能可以不经修改地使用,使用该方法.)

2. 第二种选择是利用可选LOCAL参数add-hook使得指定函数缓冲局部.使用这种方法,您可以编写钩子,如下所示:

   (add-hook 'python-mode-hook 'cr/python-mode-shell-setup)
   
   (defun cr/python-mode-shell-setup ()
     (add-hook 'hack-local-variables-hook
               (lambda () (message "virtualenv-name is %s" cr/virtualenv-name)
                 (let ((python-base (cr/virtualenv)))
                   (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
                          (setq python-python-command (concat python-base "/bin/ipython"))
                          (setq py-python-command (concat python-base "/bin/ipython"))
                          (setq py-python-command-args '( "-colors" "NoColor")))
                         (t
                          (setq python-python-command (concat python-base "/bin/python"))
                          (setq py-python-command (concat python-base "/bin/python"))
                          (setq py-python-command-args nil)))))
               nil t)) ; buffer-local hack-local-variables-hook
   

   ie python-mode-hook先运行并hack-local-variables-hook仅为当前缓冲区注册匿名函数; 然后在处理局部变量后调用该函数.

3. Lindydancer的评论提示第三种方法.它不像其他两个一样干净,但无论如何都证明它很有趣.我不喜欢导致(hack-local-variables)被调用两次的想法,但我看到如果你在local-enable-local-variables本地设置缓冲区,它会阻止(hack-local-variables)做任何事情,所以你可以这样做:

   (defun cr/python-mode-shell-setup ()
     (report-errors "File local-variables error: %s"
       (hack-local-variables)))
     (set (make-local-variable 'local-enable-local-variables) nil)
     (let ((python-base (cr/virtualenv)))
       ...))
   

   显然,稍微修改了正常的执行顺序,因此副作用可能是可能的.我担心如果文件中的局部变量注释设置了相同的主要模式,这可能会导致无限递归,但实际上这似乎不是问题.

   局部变量头注释(例如-*- mode: foo -*-)由处理(set-auto-mode),所以这些是好的; 但是mode: foo Local Variables:注释似乎是一个问题,因为它是由处理的(hack-local-variables),所以如果模式设置的方式,我认为它会导致递归.

   在实践中,我能够通过使用一个简单的函数作为'模式'来触发问题,它只是尝试运行它的钩子; 然而,使用"正确"模式进行测试并没有出现问题,因此实际上它可能是安全的.我没有进一步研究(因为其他两个解决方案比这更清晰),但我猜想延迟模式挂钩机制可能解释了它？