在子列表中检查关键字的出现次数

Question

我有一个数据结构,由列表中的属性列表组成,它们本身位于列表中.基本上是2d的plist矩阵.它的形式如下:

(((:VALUE 0 :GROUP 0) (:VALUE 0 :GROUP 0))
 ((:VALUE 0 :GROUP 0) (:VALUE 0 :GROUP 0))
 ((:VALUE 0 :GROUP 0) (:VALUE 0 :GROUP 0)))

每个:value和:group将包含一个任意整数值.我需要查找是否有任何:group关键字为0.我一直在尝试使用该member函数实现此功能,但它只会返回nil.

假设调用了数据结构,我的代码data是:

(member '(:group 0) data :test 'equal))

如何使用该member函数检查:group 0子列表子列表中的事件？(如果确实可能,或者我应该使用几个循环来迭代？)

Answer 1

尝试getf作为:key 用于find/find-if 和/或remove/remove-if-not:

1级嵌套

准备数据

(defparameter *data-1*
  (loop repeat 10 collect (list :value (random 10) :group (random 10))))
*data-1*
((:VALUE 7 :GROUP 4) (:VALUE 9 :GROUP 6) (:VALUE 2 :GROUP 7) (:VALUE 8 :GROUP 2)
 (:VALUE 5 :GROUP 6) (:VALUE 4 :GROUP 7) (:VALUE 3 :GROUP 5) (:VALUE 8 :GROUP 7)
 (:VALUE 0 :GROUP 3) (:VALUE 5 :GROUP 5))

答:找到第 7组的第一次出现:

(find 7 *data-1* :key (lambda (pl) (getf pl :group)))
==> (:VALUE 2 :GROUP 7)

B:查找第7组的所有事件:

(remove 7 *data-1* :key (lambda (pl) (getf pl :group)) :test-not #'eql)
==> ((:VALUE 2 :GROUP 7) (:VALUE 4 :GROUP 7) (:VALUE 8 :GROUP 7))

2级嵌套

准备数据:

(defparameter *data-2*
  (loop repeat 10 collect
      (loop repeat (random 4) collect
          (list :value (random 10) :group (random 10)))))
*data-2*
(((:VALUE 9 :GROUP 9) (:VALUE 8 :GROUP 2) (:VALUE 6 :GROUP 7)) NIL
 ((:VALUE 9 :GROUP 5)) ((:VALUE 9 :GROUP 1)) NIL
 ((:VALUE 2 :GROUP 7) (:VALUE 6 :GROUP 5) (:VALUE 2 :GROUP 1))
 ((:VALUE 1 :GROUP 4) (:VALUE 5 :GROUP 5))
 ((:VALUE 9 :GROUP 7) (:VALUE 9 :GROUP 8) (:VALUE 7 :GROUP 4))
 ((:VALUE 4 :GROUP 7)) NIL)

C:找到第 7组的第一次出现:

(find-if (lambda (l)
           (find 7 l :key (lambda (pl) (getf pl :group))))
         *data-2*)
==> ((:VALUE 9 :GROUP 9) (:VALUE 8 :GROUP 2) (:VALUE 6 :GROUP 7))

D:查找第7组的所有事件:

(remove-if-not (lambda (l)
                 (find 7 l :key (lambda (pl) (getf pl :group))))
               *data-2*)
==>
(((:VALUE 9 :GROUP 9) (:VALUE 8 :GROUP 2) (:VALUE 6 :GROUP 7))
 ((:VALUE 2 :GROUP 7) (:VALUE 6 :GROUP 5) (:VALUE 2 :GROUP 1))
 ((:VALUE 9 :GROUP 7) (:VALUE 9 :GROUP 8) (:VALUE 7 :GROUP 4))
 ((:VALUE 4 :GROUP 7)))

定义功能:

根据您的需要,您可能希望定义函数

(defun get-group (plist)
  (getf plist :group))
(defun find-group (list-of-plists group)
  (find group list-of-plists :key #'get-group))
(defun make-group-finder (group)
  (lambda (list-of-plists) (find-group list-of-plists group)))

现在您可以将它们用于上述任务:

A: (find-group *data-1* 7)

B: (remove 7 *data-1* :key #'get-group :test-not #'eql)

C: (find-if (make-group-finder 7) *data-2*)

d: (remove-if-not (make-group-finder 7) *data-2*)

PS remove-if-not是"过滤器"的Lisp习语.