如何在Excel VBA中获取数组中元素的子集？

Question

如何在Excel VBA中获取数组中的第3个到第6个元素？像下面这样的东西。

    Dim x(9) as variant, y(3) as variant

    y(0:3) = x(2:5)

Answer 1

在 VBA 中，与 Python 等不同，我们不能直接对数组进行“子集化”。

我们只能通过指定i和j位于某些边界之间来循环获取感兴趣的索引，例如i位于第 1 行和第 2 行之间、j位于第 2 行和第 3 列之间。当然，我们也可以直接按位置索引到数组，例如arr(1)。 i只是一个代表行索引、j列索引的变量。

或者，我们可以使用Index“切片”出特定的行或列；我想你可能会称之为子集，但从你的语法来看，我认为你正在以 python 的方式思考。

Application.WorksheetFunction.Index(array,n, 0)n将从数组中切出行

Application.WorksheetFunction.Index(array, 0, n)将从n数组中切出列

Option Explicit

Public Sub ArrayStuff()
    Dim arr(0 To 5) As Long, i As Long
    For i = 0 To 5
        arr(i) = i
    Next

    'Loop only required indices
    For i = 2 To 3
        Debug.Print arr(i)
    Next

    'Slice via Application.WorksheetFunction.Index
    Dim arr2(0 To 2, 0 To 2) As Long, j As Long, counter As Long

    For i = LBound(arr2, 1) To UBound(arr2, 1) '<==  here can specify particular rows
        For j = LBound(arr2, 2) To UBound(arr2, 2) '<== here can specify particular columns
            counter = counter + 1
            arr2(i, j) = counter
        Next
    Next

    MsgBox Join(Application.WorksheetFunction.Transpose(Application.WorksheetFunction.Index(arr2, 0, 1)), ",") 'slice a column out
    MsgBox Join(Application.WorksheetFunction.Index(arr2, 1, 0), ",") 'slice a row out
    MsgBox Join(Application.WorksheetFunction.Index(arr2, 2, 0), ",") 'slice a row out
End Sub