XSLT组半小时

Question

鉴于此XML:

<root>
  <row>
    <time>08:00</time>
    <sales>800</sales>
  </row>
  <row>
    <time>08:15</time>
    <sales>815</sales>
  </row>
  <row>
    <time>08:30</time>
    <sales>830</sales>
  </row>
  <row>
    <time>08:45</time>
    <sales>845</sales>
  </row>
  <row>
    <time>11:00</time>
    <sales>1100</sales>
  </row>
  <row>
    <time>11:45</time>
    <sales>1145</sales>
  </row>
  <row>
    <time>14:15</time>
    <sales>1415</sales>
  </row>
  <row>
    <time>14:30</time>
    <sales>1430</sales>
  </row>
</root>

我试图通过30分钟的间隔总结销售来找到一种方法来进行XSLT转换.我可以使用MUENCHIAN方法按小时间隔60分钟进行汇总,但我不能使用它30分钟,因为我需要一个自定义函数来执行此操作(但我不能使用XSLT 2.0,也不能使用.Net的自定义函数).请帮忙!

预期的输出是这样的:

30 minute
08:00 $1600  
08:30 $1675 
11:00 $1100 
11:30 $1145 
14:00 $1415 
14:30 $1430 

Answer 1

解决方案1.

这种转变:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:key name="krowsInHalfHour" match=
  "row[not((substring-after(time,':')+30) mod 30 = 0)]"
  use="generate-id(
        preceding-sibling::row
          [60*substring-before(time,':')
          +
           substring-after(time,':')
          >=
           60*substring-before(current()/time,':')
          +
           substring-after(current()/time,':')

          -
           substring-after(current()/time,':') mod 30

          ]
             [1]
                   )
  "/>

 <xsl:template match=
  "row[(substring-after(time,':')+30) mod 30 = 0
     or
      not(
       60*substring-before(preceding-sibling::row[1]/time,':')
          +
           substring-after(preceding-sibling::row[1]/time,':')
       >=
          60*substring-before(time,':')
          +
           substring-after(time,':')

          -
           substring-after(time,':') mod 30
          )
      ]
  ">
  <xsl:variable name="vPrevStartMins" select=
  "60*substring-before(time,':')
  +
   substring-after(time,':')

  -
   substring-after(time,':') mod 30
  "/>
  <xsl:value-of select=
   "concat('&#xA;',floor($vPrevStartMins div 60),
           ':', concat(substring('0',($vPrevStartMins mod 60 >0)+1),
                       $vPrevStartMins mod 60
                       )
           )
   "/>
  <xsl:text> $</xsl:text>
  <xsl:value-of select=
  "sum(sales
      |
       key('krowsInHalfHour',generate-id())/sales)"/>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

当应用于提供的XML文档时:

<root>
    <row>
        <time>08:00</time>
        <sales>800</sales>
    </row>
    <row>
        <time>08:15</time>
        <sales>815</sales>
    </row>
    <row>
        <time>08:30</time>
        <sales>830</sales>
    </row>
    <row>
        <time>08:45</time>
        <sales>845</sales>
    </row>
    <row>
        <time>11:00</time>
        <sales>1100</sales>
    </row>
    <row>
        <time>11:45</time>
        <sales>1145</sales>
    </row>
    <row>
        <time>14:15</time>
        <sales>1415</sales>
    </row>
    <row>
        <time>14:30</time>
        <sales>1430</sales>
    </row>
</root>

产生想要的,正确的结果:

8:00 $1615
8:30 $1675
11:00 $1100
11:30 $1145
14:00 $1415
14:30 $1430

解决方案2:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" >
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <my:halfHours>
  <t>00:00</t><t>00:30</t><t>01:00</t><t>01:30</t>
  <t>02:00</t><t>02:30</t><t>03:00</t><t>03:30</t>
  <t>04:00</t><t>04:30</t><t>05:00</t><t>05:30</t>
  <t>06:00</t><t>06:30</t><t>07:00</t><t>07:30</t>
  <t>08:00</t><t>08:30</t><t>09:00</t><t>09:30</t>
  <t>10:00</t><t>10:30</t><t>11:00</t><t>11:30</t>
  <t>12:00</t><t>12:30</t><t>13:00</t><t>13:30</t>
  <t>14:00</t><t>14:30</t><t>15:00</t><t>15:30</t>
  <t>16:00</t><t>16:30</t><t>17:00</t><t>17:30</t>
  <t>18:00</t><t>18:30</t><t>19:00</t><t>19:30</t>
  <t>20:00</t><t>20:30</t><t>21:00</t><t>21:30</t>
  <t>22:00</t><t>22:30</t><t>23:00</t><t>23:30</t>
  <t>24:00</t>
 </my:halfHours>

 <xsl:variable name="vhalfHrs" select=
  "document('')/*/my:halfHours/*"/>

 <xsl:template match="row">
  <xsl:variable name="vStart" select=
  "$vhalfHrs[translate(.,':','')
            >
             translate(current()/time,':','')
             ][1]
                 /preceding-sibling::*[1]
  "/>

  <xsl:variable name="vprecRow" select=
   "preceding-sibling::*[1]"/>

  <xsl:if test=
   "not(translate($vprecRow/time,':','')
       >=
       translate($vStart,':','')
       )">
   <xsl:value-of select="concat('&#xA;',$vStart, ' $')"/>
   <xsl:value-of select=
   "sum(sales|following-sibling::*
          [not(translate(time,':','')
              >=
               translate($vStart/following-sibling::*,':','')
               )
          ]
            /sales
        )
   "/>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于同一XML文档时,再次生成所需的正确结果:

08:00 $1615
08:30 $1675
11:00 $1100
11:30 $1145
14:00 $1415
14:30 $1430

说明:

1. 在变量中,$vhalfHrs我们有元素,其值是白天每半小时的开始时间.

2. 在匹配每个的模板中row,$vStart变量设置为这半小时的开始时间,其中time当前节点(row)落入其中.

3. 变量$vprecRow设置为row当前的兄弟()row.

4. 如果前面的时间row不晚于开始 - 半小时 - 时间(在$ vStart ), then the current行中)是这半小时内的第一个.

5. 我们输出起始半小时的时间.

6. 我们计算并输出同一半小时时间段内所有row元素的总和time.他们跟随当前的兄弟姐妹,row他们time不会大于或等于下一个半小时的开始.

解决方案3(XSLT 2.0):

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output method="text"/>

 <xsl:template match="/*">
  <xsl:for-each-group select="row" group-adjacent=
  "(xs:integer(substring-before(time,':'))*60
   +
    xs:integer(substring-after(time,':'))
    )
    idiv 30
  ">
   <xsl:variable name="vStartMinutes"
        select="current-grouping-key()*30"/>
   <xsl:value-of separator="" select=
   "'&#xA;',
     format-number($vStartMinutes idiv 60, '00'), ':',
     format-number($vStartMinutes mod 60,'00'),
     ' $',
     sum(current-group()/sales/xs:integer(.))
   "/>
  </xsl:for-each-group>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于与上面相同的XML文档时,会生成相同的想要的正确结果:

08:00 $1615
08:30 $1675
11:00 $1100
11:30 $1145
14:00 $1415
14:30 $1430

说明:

1. 我们使用<xsl:for-each-group>与所述group-adjacent属性设置为表达式计算1/2小时期间在其中的位置row/time是.

2. 大量使用标准功能 current-group()和current-grouping-key().