F#匹配问题

Question

这是我到目前为止:

type u = {str : string} //some type that has some property str (for simplicity, only one)
type du=
   | A of u
   | B of u // some discriminated union that carries u with it

然后,在某个地方,我有一个du序列,我正在做distinctBy和属性做的不同是str.我能想出的最好的是:

Seq.distinctBy (fun d -> match d with (A u|B u) -> u.str)

代码有效,但我不喜欢在受歧视的联盟的a和b上匹配,并希望用某些东西替换匹配.

问题是什么？:)

编辑:

在我的情况下,被区分的联合的a和b将总是带有相同的类型u,一个解决方案是摆脱du并添加它的字符串形式来输入u并简化整个混乱,但我想保留它现在的方式,因为我打算在a和b上做匹配...

Answer 1

作为du的财产,这次比赛怎么样？

type u = {str : string}

type du =
    | A of u
    | B of u with
    member this.U =
        match this with
        (A u | B u) -> u

[A {str="hello"}; B {str="world"}; A {str="world"}]
|> Seq.distinctBy (fun x -> x.U.str)

//val it : seq<du> = seq [A {str = "hello";}; B {str = "world";}]

但是,我有一些想法可以更好地模拟你和你之间的关系,同时满足你的"编辑"关注.一种方法是简单地使用元组:

type u = {str : string}

type du =
    | A
    | B

//focus on type u
[A, {str="hello"}; B, {str="world"}; A, {str="world"}]
|> Seq.distinctBy (fun (_,x) -> x.str)
//val it : seq<du * u> = seq [(A, {str = "hello";}); (B, {str = "world";})]

//focus on type du
let x = A, {str="hello"}
match x with
| A,_ -> "A"
| B,_ -> "B"
//val it : string = "A"

另一种方法是切换它并将du添加到u:

type du =
    | A
    | B

type u = { case : du; str : string}

//focus on type u
[{case=A; str="hello"}; {case=B; str="world"}; {case=A; str="world"}]
|> Seq.distinctBy (fun x -> x.str)
//val it : seq<u> = seq [{case = A;
//                        str = "hello";}; {case = B;
//                                          str = "world";}]

//focus on type du
let x = {case=A; str="hello"}
match x with
| {case=A} -> "A"
| {case=B} -> "B"
//val it : string = "A"