是否有使Perl模块或技术更容易使用长命名空间？

Question

一些名称空间很长且很烦人.可以说我下载了名为FooFoo-BarBar-BazBaz.tar.gz的假设包,它有以下模块:

FooFoo::BarBar::BazBaz::Bill
FooFoo::BarBar::BazBaz::Bob
FooFoo::BarBar::BazBaz::Ben
FooFoo::BarBar::BazBaz::Bozo
FooFoo::BarBar::BazBaz::Brown
FooFoo::BarBar::BazBaz::Berkly
FooFoo::BarBar::BazBaz::Berkly::First
FooFoo::BarBar::BazBaz::Berkly::Second

是否有一个我可以使用的模块或技术类似于C++'using'语句,即有没有办法可以做

using FooFoo::BarBar::BazBaz;

然后我会这样做

my $obj = Brown->new();

ok $obj->isa('FooFoo::BarBar::BazBaz::Brown') ;  # true
# or...
ok $obj->isa('Brown'); # also true

Answer 1

该别名编译做到这一点:

use aliased 'FooFoo::BarBar::BazBaz::Bill';

my $bill = Bill->new;

aliased 是语法糖

use constant Bill => 'FooFoo::BarBar::BazBaz::Bill';
# or 
sub Bill () {'FooFoo::BarBar::BazBaz::Bill'}

这样做的缺点是包名称作为参数的正常使用是使用带引号的字符串完成的:

$obj->isa('FooFoo::BarBar::BazBaz::Bill')

但是常量子程序需要一个简单的说法:

$obj->isa(Bill);

这似乎是一个等待发生的错误.

或者,您可以使用Perl内置的名称空间别名支持:

package Foo::Bar::Baz::Bill;

sub new {bless {}}

package Foo::Bar::Baz::Tom;

sub new {bless {}}

package main;

BEGIN {*FBB:: = *Foo::Bar::Baz::}  # the magic happens here

say FBB::Bill->new;  # Foo::Bar::Baz::Bill=HASH(0x80fd10)

say FBB::Tom->new;   # Foo::Bar::Baz::Tom=HASH(0xfd1080)

关于->isa('shortname')需求,别名的stash方法像往常一样使用带引号的字符串:

my $obj = FBB::Bill->new;

say $obj->isa('FBB::Bill');           # prints 1
say $obj->isa('Foo::Bar::Baz::Bill'); # prints 1

编译时别名的影响BEGIN {*short:: = *long::package::name::}在所有包和作用域中都是全局的.只要你选择一个空包来别名就可以了.