通过XSLT格式化XML格式的日期

Question

当我使用XML序列化程序序列化a时DateTime,它使用以下格式编写:

<Date>2007-11-14T12:01:00</Date>

当通过XSLT样式表传递它以输出HTML时,我该如何格式化？在大多数情况下,我只需要约会,当我需要时间时,我当然不希望那里有"有趣的T".

Answer 1

以下是一些可以使用的1.0模板: -

<xsl:template name="formatDate">
    <xsl:param name="dateTime" />
    <xsl:variable name="date" select="substring-before($dateTime, 'T')" />
    <xsl:variable name="year" select="substring-before($date, '-')" />
    <xsl:variable name="month" select="substring-before(substring-after($date, '-'), '-')" />
    <xsl:variable name="day" select="substring-after(substring-after($date, '-'), '-')" />
    <xsl:value-of select="concat($day, ' ', $month, ' ', $year)" />
</xsl:template>

<xsl:template name="formatTime">
    <xsl:param name="dateTime" />
    <xsl:value-of select="substring-after($dateTime, 'T')" />
</xsl:template>

打电话给他们: -

    <xsl:call-template name="formatDate">
        <xsl:with-param name="dateTime" select="xpath" />
    </xsl:call-template>

和

    <xsl:call-template name="formatTime">
        <xsl:with-param name="dateTime" select="xpath" />
    </xsl:call-template>

其中xpath是具有标准日期时间格式的元素或属性的路径.

Answer 2

在XSLT 1.0中,日期格式化并不容易.可能最优雅的方法是在C#中编写一个简短的XSLT扩展函数来进行日期格式化.这是一个例子:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt"
                xmlns:myExtension="urn:myExtension"
                exclude-result-prefixes="msxsl myExtension">
  <xsl:output method="xml" indent="yes"/>

  <msxsl:script implements-prefix="myExtension" language="C#">
    <![CDATA[
      public string FormatDateTime(string xsdDateTime, string format)
      {
          DateTime date = DateTime.Parse(xsdDateTime);
          return date.ToString(format); 
      }

    ]]>
  </msxsl:script>

  <xsl:template match="date">
    <formattedDate>
      <xsl:value-of select="myExtension:FormatDateTime(self::node(), 'd')"/>
    </formattedDate>
  </xsl:template>
</xsl:stylesheet>

有了这个输入文件

<?xml version="1.0" encoding="utf-8"?>
<date>2007-11-14T12:01:00</date>

你会得到

<?xml version="1.0" encoding="utf-8"?>
<formattedDate>14.11.2007</formattedDate> 

格式化日期的函数将日期值作为字符串和DateTime.ToString方法中描述的格式.使用.NET的DateTime结构,您可以免费解析任意XSD日期时间值(包括时区说明符),时区计算和本地化输出.

但是,请注意有一个警告(http://support.microsoft.com/kb/316775)与msxml脚本扩展:每次加载XSLT时,包含脚本代码的程序集将动态生成并加载到内存中.由于.NET运行时的设计,无法卸载此程序集.这就是为什么你必须确保你的XSLT只加载一次(然后缓存以供进一步重用).在IIS中运行时,这一点尤为重要.

Answer 3

约翰·沃克曼讨论了这个问题,在长度和在此给出了几种解决方案的讨论^[1]在他的博客.基本上,解析各个日期组件并按您希望的顺序重新组合.对于您的情况,纯XSLT 1.0+版本将是:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="date">
<!-- converts FROM <date>2001-12-31T12:00:00</date> TO some new format (DEFINED below) -->
<xsl:template name="FormatDate">
<xsl:param name="DateTime" />

<xsl:variable name="year" select="substring($DateTime,1,4)" />
<xsl:variable name="month-temp" select="substring-after($DateTime,'-')" />
<xsl:variable name="month" select="substring-before($month-temp,'-')" />
<xsl:variable name="day-temp" select="substring-after($month-temp,'-')" />
<xsl:variable name="day" select="substring($day-temp,1,2)" />
<xsl:variable name="time" select="substring-after($DateTime,'T')" />
<xsl:variable name="hh" select="substring($time,1,2)" />
<xsl:variable name="mm" select="substring($time,4,2)" />
<xsl:variable name="ss" select="substring($time,7,2)" />

<!-- EUROPEAN FORMAT -->
<xsl:value-of select="$day"/>
<xsl:value-of select="'.'"/> <!--18.-->
<xsl:value-of select="$month"/>
<xsl:value-of select="'.'"/> <!--18.03.-->
<xsl:value-of select="$year"/>
<xsl:value-of select="' '"/> <!--18.03.1976 -->
<xsl:value-of select="$hh"/>
<xsl:value-of select="':'"/> <!--18.03.1976 13: -->
<xsl:value-of select="$mm"/>
<xsl:value-of select="':'"/> <!--18.03.1976 13:24 -->
<xsl:value-of select="$ss"/> <!--18.03.1976 13:24:55 -->
<!-- END: EUROPEAN FORMAT -->

</xsl:template>

另一种格式(REPLACEs EUROPEAN FORMAT部分):

<!-- Long DATE FORMAT -->
<xsl:choose>
<xsl:when test="$month = '1' or $month= '01'">January</xsl:when>
<xsl:when test="$month = '2' or $month= '02'">February</xsl:when>
<xsl:when test="$month= '3' or $month= '03'">March</xsl:when>
<xsl:when test="$month= '4' or $month= '04'">April</xsl:when>
<xsl:when test="$month= '5' or $month= '05'">May</xsl:when>
<xsl:when test="$month= '6' or $month= '06'">June</xsl:when>
<xsl:when test="$month= '7' or $month= '07'">July</xsl:when>
<xsl:when test="$month= '8' or $month= '08'">August</xsl:when>
<xsl:when test="$month= '9' or $month= '09'">September</xsl:when>
<xsl:when test="$month= '10'">October</xsl:when>
<xsl:when test="$month= '11'">November</xsl:when>
<xsl:when test="$month= '12'">December</xsl:when>
</xsl:choose> 
<xsl:value-of select="' '"/> <!--January -->
<xsl:value-of select="$day"/> <!--January 12 -->
<xsl:value-of select="','"/> <!--January 12,-->
<xsl:value-of select="' '"/> <!--January 12, -->
<xsl:value-of select="$year"/> <!--January 12, 2001-->
<!-- END: Long DATE FORMAT -->

您可以以任何方式重新组合元素.

[1] http://geekswithblogs.net/workdog/archive/2007/02/08/105858.aspx @@ http://archive.is/4Hjep

Answer 4

抱歉评论这个旧线程,但对于其他人发现它像我一样你也可以使用javascript如果你使用MS变压器:

声明"msxsl"命名空间:

xmlns:msxsl="urn:schemas-microsoft-com:xslt" 

声明脚本的命名空间:

xmlns:js="urn:custom-javascript" 

(可选)省略输出中的前缀:

exclude-result-prefixes="msxsl js" 

所以你最终会得到一个像这样的xsl声明:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"
  xmlns:js="urn:custom-javascript"
  exclude-result-prefixes="msxsl js">

在msxsl:script元素中编写JavaScript:

<msxsl:script language="JavaScript" implements-prefix="js"> 
<![CDATA[ 
function javascriptFunction(dateValue){
  var date = new Date(dateValue);
  if(!isNaN(date)) return date.toLocaleString();
  return dateValue;
}
]]>
</msxsl:script>

调用您的JavaScript函数(使用XPath语法'.'表示'此节点'):

<xsl:value-of select="js:javascriptFunction(string(.))"/>

注意:在编写时,似乎没有(xsl)方式包含外部js文件(例如jquery库).这可以通过在转换之前解析xsl文件服务器端并将js文件内容作为字符串添加到CDATA部分来完成.我自己开始沿着这条路走下去但得出的结论是,如果你需要这个级别的功能,它可能会更好地放在管道的不同部分.

来源:http://dev.ektron.com/kb_article.aspx
？id = 482 ref:http://www.ibm.com/developerworks/xml/library/x-tipxsltjs/index.html