如何在Haskell中拆分字符串？

Question

是否有一种在Haskell中拆分字符串的标准方法？

lines和words上一个空格或换行从拆分工作的伟大,但肯定没有拆就一个逗号一个标准的方式？

我在Hoogle上找不到它.

具体来说,我正在寻找split "," "my,comma,separated,list"回报的东西["my","comma","separated","list"].

Answer 1

请记住,您可以查找Prelude函数的定义!

http://www.haskell.org/onlinereport/standard-prelude.html

看那里,定义words是,

words   :: String -> [String]
words s =  case dropWhile Char.isSpace s of
                      "" -> []
                      s' -> w : words s''
                            where (w, s'') = break Char.isSpace s'

因此,将其更改为带谓词的函数:

wordsWhen     :: (Char -> Bool) -> String -> [String]
wordsWhen p s =  case dropWhile p s of
                      "" -> []
                      s' -> w : wordsWhen p s''
                            where (w, s'') = break p s'

然后用你想要的任何谓词来调用它!

main = print $ wordsWhen (==',') "break,this,string,at,commas"

Answer 2

有一个称为拆分的包.

cabal install split

像这样使用它:

ghci> import Data.List.Split
ghci> splitOn "," "my,comma,separated,list"
["my","comma","separated","list"]

它带有许多其他功能,用于拆分匹配的分隔符或具有多个分隔符.

Answer 3

如果您使用Data.Text,则有splitOn:

http://hackage.haskell.org/packages/archive/text/0.11.2.0/doc/html/Data-Text.html#v:splitOn

这是在Haskell平台中构建的.

例如:

import qualified Data.Text as T
main = print $ T.splitOn (T.pack " ") (T.pack "this is a test")

要么:

{-# LANGUAGE OverloadedStrings #-}

import qualified Data.Text as T
main = print $ T.splitOn " " "this is a test"

Answer 4

在模块Text.Regex(Haskell平台的一部分)中,有一个函数:

splitRegex :: Regex -> String -> [String]

它根据正则表达式拆分字符串.该API可以在Hackage中找到.

Answer 5

试试这个:

import Data.List (unfoldr)

separateBy :: Eq a => a -> [a] -> [[a]]
separateBy chr = unfoldr sep where
  sep [] = Nothing
  sep l  = Just . fmap (drop 1) . break (== chr) $ l

仅适用于单个字符,但应易于扩展.

Answer 6

使用Data.List.Split,使用split:

[me@localhost]$ ghci
Prelude> import Data.List.Split
Prelude Data.List.Split> let l = splitOn "," "1,2,3,4"
Prelude Data.List.Split> :t l
l :: [[Char]]
Prelude Data.List.Split> l
["1","2","3","4"]
Prelude Data.List.Split> let { convert :: [String] -> [Integer]; convert = map read }
Prelude Data.List.Split> let l2 = convert l
Prelude Data.List.Split> :t l2
l2 :: [Integer]
Prelude Data.List.Split> l2
[1,2,3,4]

Answer 7

split :: Eq a => a -> [a] -> [[a]]
split d [] = []
split d s = x : split d (drop 1 y) where (x,y) = span (/= d) s

例如

split ';' "a;bb;ccc;;d"
> ["a","bb","ccc","","d"]

将删除单个尾随分隔符:

split ';' "a;bb;ccc;;d;"
> ["a","bb","ccc","","d"]

Answer 8

在不导入任何字符的情况下，无需将一个字符直接替换为空格，words而是将目标分隔符作为空格。就像是：

words [if c == ',' then ' ' else c|c <- "my,comma,separated,list"]

要么

words let f ',' = ' '; f c = c in map f "my,comma,separated,list"

您可以使它成为带有参数的函数。您可以消除匹配多个字符的参数，例如：

 [if elem c ";,.:-+@!$#?" then ' ' else c|c <-"my,comma;separated!list"]

Answer 9

我昨天开始学习Haskell,如果我错了,请纠正我,但是:

split :: Eq a => a -> [a] -> [[a]]
split x y = func x y [[]]
    where
        func x [] z = reverse $ map (reverse) z
        func x (y:ys) (z:zs) = if y==x then 
            func x ys ([]:(z:zs)) 
        else 
            func x ys ((y:z):zs)

得到:

*Main> split ' ' "this is a test"
["this","is","a","test"]

或许你想要

*Main> splitWithStr  " and " "this and is and a and test"
["this","is","a","test"]

这将是:

splitWithStr :: Eq a => [a] -> [a] -> [[a]]
splitWithStr x y = func x y [[]]
    where
        func x [] z = reverse $ map (reverse) z
        func x (y:ys) (z:zs) = if (take (length x) (y:ys)) == x then
            func x (drop (length x) (y:ys)) ([]:(z:zs))
        else
            func x ys ((y:z):zs)

Answer 10

我觉得这更容易理解：

split :: Char -> String -> [String]
split c xs = case break (==c) xs of 
  (ls, "") -> [ls]
  (ls, x:rs) -> ls : split c rs

Answer 11

我不知道如何在Steve的答案中添加评论,但我想推荐
  GHC库文档,
特别是
  Data.List中的Sublist函数.

作为参考,这比阅读简单的Haskell报告要好得多.

通常,关于何时创建新的子列表以供应的规则的折叠也应该解决它.