替换 Excel 电源查询中的 SQL 查询参数

Question

我有一个工作簿，我在其中使用 SQL 查询的固定参数值从 SQL Server 获取数据。

我想制作另一个工作表，并从单元格值中获取 SQL 查询的参数。

我没有发现任何关于这方面的信息。

另外，我想在另一个工作表中的单元格值发生变化时立即刷新数据。

Answer 1

为此，您需要设置三个不同的部分：

1) Excel 表格中的参数表

2) PowerQuery 中高级编辑器的更改

3）当参数表中的任何单元格被更改时刷新PQ的宏

1）Excel表格

你可以看到我包含了一个名为的列param，它可以保存一个参数名称，以帮助明确哪个参数是哪个。

2) PQ 高级编辑器

let
    ParamTable = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    Param = "'" & Text.From(ParamTable[value]{0}) & "'",
    Source = Sql.Database("IP Address", "Database Name", [Query="Select * from weeks#(lf)where date >= '2018-01-01' and date < " &Param])
in
    Source

等效替代方案： （SQL 查询中使用的变量位置不同。）

let
    ParamTable = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    Param = "'" & Text.From(ParamTable[value]{0}) & "'",
    Source = Sql.Database("IP Address", "Database Name", [Query="Select * from weeks#(lf)where date < " &Param & " and date >= '2018-01-01'"])
in
    Source

替代变量类型：（如果处理数字，则'不需要字符串标记）

let
    ParamTable = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    Param = Text.From(ParamTable[value]{0}),
    Source = Sql.Database("IP Address", "Database Name", [Query="Select * from weeks#(lf)where cnt < " &Param & " and date >= '2018-01-01'"])
in
    Source

解释：

将参数表拉入 PQ 查询 ( ParamTable = Excel.CurrentWorkbook(){[Name="Table1"]}[Content]) 后，可以通过列名访问列，[value]并通过零索引号访问行{0}。因为我正在拉一个日期值。我需要将它转换为我可以插入到 SQL 查询中的字符串值——因此将'sText.From()和附加'到末尾（SQL 用单个 ' 而不是双 " 标记字符串）

由于我将变量命名为Param在字符串中使用它，因此我替换&Param了最初存在的值。

2.1 Power Query 的 Value.NativeQuery

let
    ParamTable = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    Param = ParamTable[value]{0},
    Source = Value.NativeQuery(Sql.Database("IP Address", "Database Name"), "Select * from weeks where date < @dateSel and date >= '2018-01-01'",[dateSel = Param])
in
    Source

替代格式：

let
    ParamTable = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    Param = ParamTable[value]{0},
    Source = Sql.Database("IP Address", "Database Name"),
    Data = Value.NativeQuery(Source, "

Select * from weeks
where date < @dateSel and date >= '2018-01-01'

",[dateSel = Param])
in
    Source

笔记：

使用时Value.NativeQuery()，您可以将日期或日期时间值作为变量直接传入，而无需包含单个撇号。

有时将数据检索分成一个Source步骤和一个NativeQuery步骤可以帮助解决 PQ 的零星防火墙问题。

3) 宏

这适用于简单检查表中的任何内容是否已更改，然后运行刷新。您需要确保将其放置在正确的模块中。您需要更改的项目是：

• Sheet1 是带有参数表的工作表的代号。
• "Table" 是参数表的名称
• "Query - Query1" 是要刷新的连接的名称

注意： Query1是查询的名称。连接的默认名称通常是Query -& 查询名称

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Sheet1.ListObjects("Table1").DataBodyRange) Is Nothing Then
        ThisWorkbook.Connections("Query - Query1").Refresh
    End If
End Sub