如何为表单的标题栏,系统菜单图标和最小化,最大化和关闭按钮设置自定义光标？

Question

是否有Windows API为表单的标题栏,系统菜单图标和最小化,最大化和关闭按钮设置自定义光标？

我有一个加载和设置给定控件的游标的功能:

type

 TFrm_Main = class(TForm)
   ....
 private
  procedure SetCursor_For(AControl: TControl; ACursor_FileName: string;
    Const ACurIndex: Integer);
 ...
 end;
 const
   crOpenCursor = 1;
   crRotateCursor = 2;
   crCursor_Water = 3;

 var
   Frm_Main: TFrm_Main;
 ...
 procedure TFrm_Main.SetCursor_For(AControl: TControl; ACursor_FileName: 
  string; const ACurIndex: Integer);
 begin
   Screen.Cursors[ACurIndex] := Loadcursorfromfile(PWideChar(ACursor_FileName));
   AControl.Cursor := ACurIndex;
 end;

而我正在以这种方式使用它:

SetCursor_For(Frm_Main, 'Cursors\Cursor_Rotate.ani', crRotateCursor);

但我错过了为特定表单部分设置光标的方法,如表单标题栏,系统菜单图标和最小化,最大化和关闭按钮.有没有办法为这些表单部分设置游标？

Answer 1

处理WM_SETCURSOR消息并测试消息参数的HitTest字段以获取以下命中测试代码值之一,并使用SetCursor函数设置光标,将True返回到消息Result(Windows API宏TRUE和FALSE巧合地匹配Delphi的布尔类型值,所以你只能在那里进行类型转换):

• HTCAPTION - 标题栏
• HTSYSMENU - 系统菜单图标
• HTMINBUTTON - 最小化按钮
• HTMAXBUTTON - 最大化按钮
• HTCLOSE - 关闭按钮

例如:

type
  TForm1 = class(TForm)
  private
    procedure WMSetCursor(var Msg: TWMSetCursor); message WM_SETCURSOR;
  end;

implementation

procedure TForm1.WMSetCursor(var Msg: TWMSetCursor);
begin
  case Msg.HitTest of
    HTCAPTION:
    begin
      Msg.Result := LRESULT(True);
      Winapi.Windows.SetCursor(Screen.Cursors[crHandPoint]);
    end;
    HTSYSMENU:
    begin
      Msg.Result := LRESULT(True);
      Winapi.Windows.SetCursor(Screen.Cursors[crHelp]);
    end;
    HTMINBUTTON:
    begin
      Msg.Result := LRESULT(True);
      Winapi.Windows.SetCursor(Screen.Cursors[crUpArrow]);
    end;
    HTMAXBUTTON:
    begin
      Msg.Result := LRESULT(True);
      Winapi.Windows.SetCursor(Screen.Cursors[crSizeAll]);
    end;
    HTCLOSE:
    begin
      Msg.Result := LRESULT(True);
      Winapi.Windows.SetCursor(Screen.Cursors[crNo]);
    end;
  else
    inherited;
  end;
end;