如何在 GTK Vala 中实现 CSS 样式？

Question

我正在尝试在 GTK 中为我的标签添加 CSS 样式，但我不知道如何设置文件。我目前在开头添加了一个包含，但出现此错误：

我也不知道我是否正确实现了这一点，这对 GTK 编程来说非常新。有人可以帮我正确设置 CSS 实现吗？

#include<gtk/gtk.h>
public class MyApp : Gtk.Application {

  public MyApp() {
        Object (
              application_id: "com.github.omerntosi.gtkHangman",
              flags: ApplicationFlags.FLAGS_NONE
        );
  }

  protected override void activate() {
        var main_window = new Gtk.ApplicationWindow(this);
        main_window.set_default_size(1000,800);
        main_window.title = "GTK Hangman";

        var grid = new Gtk.Grid();
        grid.orientation = Gtk.Orientation.VERTICAL;
        grid.row_spacing = 6;

        var topHalf = new Gtk.Grid();
        topHalf.orientation = Gtk.Orientation.HORIZONTAL;
        grid.row_spacing = 6;

        var man = new Gtk.Image();
        man.set_from_file("../src/img/placeholder-500x350.png");
        topHalf.add(man);

        GtkCssProvider cssProvider = gtk_css_provider_new();
        gtk_css_provider_load_from_path(cssProvider, "style.css", NULL);
        gtk_style_context_add_provider_for_screen(gdk_screen_get_default(), GTK_STYLE_PROVIDER(cssProvider), GTK_STYLE_PROVIDER_PRIORITY_USER);

        var sol = new Gtk.Label("____ ______");
        sol.set_use_markup(true);
        topHalf.add(sol);

        grid.add(topHalf);
        main_window.add(grid);
        main_window.show_all();
  }

  public static int main(string[] args) {
        var app = new MyApp();
        return app.run(args);
  }
}

Answer 1

您将 Vala 和 C 混合在同一个文件中，我已将 C 部分翻译为 Vala：

• 删除了该#include指令。
• 将 Gtk.CssProvider 的 C 代码从 C 移植到 Vala

结果如下：

public class MyApp : Gtk.Application {

  public MyApp() {
        Object (
              application_id: "com.github.omerntosi.gtkHangman",
              flags: ApplicationFlags.FLAGS_NONE
        );
  }

  protected override void activate() {
        var main_window = new Gtk.ApplicationWindow(this);
        main_window.set_default_size(1000,800);
        main_window.title = "GTK Hangman";

        var grid = new Gtk.Grid();
        grid.orientation = Gtk.Orientation.VERTICAL;
        grid.row_spacing = 6;

        var topHalf = new Gtk.Grid();
        topHalf.orientation = Gtk.Orientation.HORIZONTAL;
        grid.row_spacing = 6;

        var man = new Gtk.Image();
        man.set_from_file("../src/img/placeholder-500x350.png");
        topHalf.add(man);

        Gtk.CssProvider css_provider = new Gtk.CssProvider ();
        css_provider.load_from_path ("style.css");
        Gtk.StyleContext.add_provider_for_screen (Gdk.Screen.get_default (), css_provider, Gtk.STYLE_PROVIDER_PRIORITY_USER);

        var sol = new Gtk.Label("____ ______");
        sol.set_use_markup(true);
        topHalf.add(sol);

        grid.add(topHalf);
        main_window.add(grid);
        main_window.show_all();
  }

  public static int main(string[] args) {
        var app = new MyApp();
        return app.run(args);
  }
}

编译用--pkg gtk+-3.0. 这将修复有关缺少 gtk.h 等的编译器消息。如果没有，那么您还没有正确安装 GTK+ 3.0 头文件（apt-get install libgtk-3-dev包）。

Vala 正在使用该pkg-config工具将 CFLAGS 和 LDFLAGS 添加到 C 编译步骤中，该步骤用于将 Vala 源文件编译为二进制文件。

生成的 C 文件将自动包含#include <gtk/gtk.h>，因为它是在 vala 编译器附带的 gtk+-3.0.vapi 文件中指定的。

如果没有资源文件，我无法测试它，但在这些更改之后，它在这里编译得很好。

留下了一个警告，因为代码没有在GLib.Error某处捕获，但您应该能够自己修复它。

这里还有另一个关于如何在 Vala 中使用 CSS 的代码示例：

/sf/answers/1992619541/