Vim-覆盖插件作用域功能

Question

我在Vim中有一个插件，我不喜欢其中一个函数的行为。但是打开拉取请求并不是一个案例，而是一个扩展。
我知道只要新定义在前一个定义之后，就可以通过使用bang作为后缀来覆盖函数。但是，如果此方法的作用域仅限于插件中的脚本，我该怎么做？
我无法在_Vim_s帮助中找到提示，也无法通过请求搜索引擎找到提示。任何人都知道这个话题，至少他可以说，这是根本没有可能的。

一个简短的例子：
plugin / autoload / plugin.vim

  ...
  function! s:foo() {
       // behavior I would like to adjust
  }
  ...

〜/ .vimrc

  function! foo() {
       // the "correct" behavior
  }

谢谢你的帮助！

Answer 1

实际上是可能的。但是正如@romainl所说，您最好向插件维护者建议您的补丁或要求一个变种点。

关于如何。

首先，您需要确定此自动加载插件的脚本编号。假设:scriptname它是210。为了自动执行此操作，lh#askvim#scriptid() 我的库插件中有一个函数可以执行此任务-请参阅答案末尾的当前定义。

然后，要覆盖此s:foo()功能，您需要为

function! <SNR>210_Foo()
   new definition
endfunction

（我刚刚在vim 8.0-1157上进行了测试）

IOW，我们可以覆盖脚本本地函数。但是，我还没有找到如何在不引用其s:字典的情况下直接覆盖脚本局部变量的方法。我们可以将setter / getter函数注入特定的变量或返回本地s:字典的函数。

lh#askvim#scriptid() 当前的定义如下

" Function: lh#askvim#execute(command) {{{3
" @since Version 4.0.0
if exists('*execute')
  function! lh#askvim#execute(command) abort
    return split(execute(a:command), "\n")
  endfunction
else
  function! lh#askvim#execute(command) abort
    return s:beware_running_through_client_server ? [] : split(lh#askvim#exe(a:command), "\n")
  endfunction
endif

" Function: lh#askvim#scriptnames() {{{3
function! lh#askvim#scriptnames() abort
  let scripts = lh#askvim#execute('scriptnames')
  let s:scripts = map(copy(scripts), 'split(v:val, "\\v:=\\s+")')
  call lh#list#map_on(s:scripts, 1, 'fnamemodify(v:val, ":p")')
  return s:scripts
endfunction

" Function: lh#askvim#scriptid(name) {{{3
function! lh#askvim#scriptid(name, ...) abort
  let last_change = get(a:, 1, 0)
  if last_change || !exists('s:scripts')
    call lh#askvim#scriptnames()
  endif
  let matches = filter(copy(s:scripts), 'v:val[1] =~ a:name')
  if len(matches) > 1
    throw "Too many scripts match `".a:name."`: ".string(matches)
  elseif empty(matches)
    if last_change
      throw "No script match `".a:name."`"
    else
      return lh#askvim#scriptid(a:name, 1)
    endif
  endif
  return matches[0][0]
endfunction