像StrTok()或Sscanf()这样的东西？

Question

所以,我正在通过串口从ModBos读取并获得如下所示的读数: '+0020.8+0022.8-00.046-00.002-00.005-001.99+00.000+00.003';

基本上,总会有8个浮点读数,前面带有加号或减号,尽管它们的字符长度可能不同.

获取值为浮点数组(或字符串数​​组或TSringList)的最有效方法是什么？

我不确定,但这可能是时间关键,所以效率可能优于优雅.

Answer 1

我会做这样的事情:

type
  TFloatArray = array[0..7] of Double;

procedure ParseFloats(const aFloatStr: string;
  var aFloatArray: TFloatArray);
var
  lPos: Integer;
  lNextPos: Integer;
  lPosPositive: Integer;
  lPosNegative: Integer;
  i: Integer;
  lFormatSettings: TFormatSettings;
begin
  //do not forget formatsettings, or you will get problems with regional settings
  lFormatSettings.DecimalSeparator := '.';
  lFormatSettings.ThousandSeparator := ',';
  lPos := 1;
  for i := 0 to High(aFloatArray) do
  begin
    lPosPositive := PosEx('+', aFloatStr, lPos + 1);
    lPosNegative := PosEx('-', aFloatStr, lPos + 1);
    if lPosPositive = 0 then
      lNextPos := lPosNegative
    else if lPosNegative = 0 then
      lNextPos := lPosPositive
    else
      lNextPos := Min(lPosPositive, lPosNegative);
    if lNextPos = 0 then
      lNextPos := Length(aFloatStr) + 1;
    aFloatArray[i] := StrToFloat(Copy(aFloatStr, lPos, lNextPos - lPos), lFormatSettings);
    lPos := lNextPos;
  end;
end;

//call like this
var
  lFloats: TFloatArray;
begin
  ParseFloats('+0020.8+0022.8-00.046-00.002-00.005-001.99+00.000+00.003', lFloats);
end;

因为总有8个浮点值,所以8个双精度数的固定数组就足够了.我将字符串操作保持在最小值,每个浮点值只复制一次字符串.重要的是TFormatSettings,否则你会在小数分隔符不是点(如我的)的系统上得到错误.

这里没有异常处理,我期望一个包含8个浮点值的字符串,仅此而已.

Answer 2

您可以下载并使用移植到Delphi的VC++ sscanf.